VBScript

Azure Blob Service - List all Containers in a Storage Account

See more Azure Cloud Storage Examples

Azure Storage Blob Service REST API: Lists all the containers in a storage account. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Azure Blob Service Example: List all of the containers in an account.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' URI parameters, such as "maxresults", are added by calling AddQueryParam
success = rest.AddQueryParam("maxresults","1000")

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

responseStr = rest.FullRequestNoBody("GET","/?comp=list")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 200 response code,
' with an XML body.  
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

' Load the XML response for parsing.
' A sample XML response containing 2 containers is shown below.
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseStr)

outFile.WriteLine(xml.GetXml())

' Iterate over the containers, listing some information about each.
success = xml.FindChild2("Containers")
numContainers = xml.NumChildren
i = 0
Do While (i < numContainers)
    success = xml.GetChild2(i)
    outFile.WriteLine("Container Name: " & xml.GetChildContent("Name"))
    lastModDateStr = xml.ChilkatPath("Properties|Last-Modified|*")
    outFile.WriteLine("Last Modified: " & lastModDateStr)
    ' The date/time string can be loaded into a CkDateTime object for conversion to other date formats..
    set dateTime = CreateObject("Chilkat.CkDateTime")
    success = dateTime.SetFromRfc822(lastModDateStr)

    leaseState = xml.ChilkatPath("Properties|LeaseState|*")
    outFile.WriteLine("Lease State: " & leaseState)

    success = xml.GetParent2()
    i = i + 1
Loop
success = xml.GetParent2()

' Sample XML response:

' 	<?xml version="1.0" encoding="utf-8" ?>
' 	<EnumerationResults ServiceEndpoint="https://chilkat.blob.core.windows.net/">
' 	    <MaxResults>1000</MaxResults>
' 	    <Containers>
' 	        <Container>
' 	            <Name>test</Name>
' 	            <Properties>
' 	                <Last-Modified>Wed, 20 Apr 2016 01:02:25 GMT</Last-Modified>
' 	                <Etag>"0x8D368B77024C583"</Etag>
' 	                <LeaseStatus>unlocked</LeaseStatus>
' 	                <LeaseState>available</LeaseState>
' 	            </Properties>
' 	        </Container>
' 	        <Container>
' 	            <Name>test2</Name>
' 	            <Properties>
' 	                <Last-Modified>Tue, 03 May 2016 17:13:01 GMT</Last-Modified>
' 	                <Etag>"0x8D373762EB6AC85"</Etag>
' 	                <LeaseStatus>unlocked</LeaseStatus>
' 	                <LeaseState>available</LeaseState>
' 	            </Properties>
' 	        </Container>
' 	    </Containers>
' 	    <NextMarker />
' 	</EnumerationResults>

outFile.Close