VBScript
AWS KMS Import PFX Key

Imports a certificate's private key from a .pfx file to new key created in AWS KMS.
Chilkat VBScript Downloads

VBScript
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example is using a relative file path.  You can also specify a full file path, such as "C:/someDir/myCertAndKey.pfx"
' or a file path the makes sense on non-Windows operating systems..
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile("qa_data/pfx/myCertAndKey.pfx","pfx_password")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Get the cert's private key.  This is what will be uploaded to AWS KMS.
set privKey = CreateObject("Chilkat.PrivateKey")
success = cert.GetPrivateKey(privKey)
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("service","aws-kms")
success = json.UpdateString("auth.access_key","AWS_ACCESS_KEY")
success = json.UpdateString("auth.secret_key","AWS_SECRET_KEY")
success = json.UpdateString("auth.region","us-west-2")
success = json.UpdateString("description","Test of uploading existing private key to AWS KMS")

' Let's add some information about the certificate this key belongs to.
' This is for informational purposes only, so that we can examine the tags
' in the AWS KMS console and know the corresponding certificate.
success = json.UpdateString("tags[0].key","CertSerial")
success = json.UpdateString("tags[0].value",cert.SerialNumber)
success = json.UpdateString("tags[1].key","CertIssuer")
success = json.UpdateString("tags[1].value",cert.IssuerCN)
success = json.UpdateString("tags[2].key","CertSubject")
success = json.UpdateString("tags[2].value",cert.SubjectCN)

success = json.UpdateString("keyUsage","SIGN_VERIFY")

' The UploadToCloud method was added in Chilkat v9.5.0.96
set jsonOut = CreateObject("Chilkat.JsonObject")
success = privKey.UploadToCloud(json,jsonOut)
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

' When successful, the jsonOut contains information about the private key in AWS KMS.
' Most importantly, the KeyId.
jsonOut.EmitCompact = 0
outFile.WriteLine(jsonOut.Emit())

' Sample JSON result:

' {
'   "AWSAccountId": "954491834127",
'   "Arn": "arn:aws:kms:us-west-2:954491834127:key/187012e8-008f-4fc7-b100-5efe6146dff2",
'   "KeySpec": "RSA_4096",
'   "Description": "Test of uploading existing private key to AWS KMS",
'   "KeyId": "187012e8-008f-4fc7-b100-5efe6146dff2",
'   "KeyUsage": "SIGN_VERIFY"
' }

outFile.Close