(VBScript) Authenticode Sign an Executable (EXE) or DLL

See more Code Signing Examples

Demonstrates how to Authenticode sign an EXE or DLL.

Note: Chilkat's code signing class was added in v9.5.0.97

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First create the following JSON to specify that SHA256 is to be used,
' and provide timestamp server information.

' {
'   "hashAlg": "sha256",
'   "timestampToken": {
'     "enabled": true,
'     "tsaUrl": "http://timestamp.digicert.com",
'     "requestTsaCert": true,
'     "hashAlg": "sha256"
'   }
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("hashAlg","sha256")
success = json.UpdateBool("timestampToken.enabled",1)
success = json.UpdateString("timestampToken.tsaUrl","http://timestamp.digicert.com")
success = json.UpdateBool("timestampToken.requestTsaCert",1)
success = json.UpdateString("timestampToken.hashAlg","sha256")

' Load a code signing certificate..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile("C:/someDir/myCodeSigningCert.pfx","pfx password")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' You can sign .exe or .dll files.
exePath = "C:/someOtherDir/HelloWorld.exe"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CodeSign")
set signer = CreateObject("Chilkat.CodeSign")

' If successful, the following call will apply the signature to the EXE (or DLL).
success = signer.AddSignature(exePath,cert,json)
If (success = 0) Then
    outFile.WriteLine(signer.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Successfully applied the Authenticode signature.")

outFile.Close