(VBScript) Async SFTP Progress Info

Demonstrates checking for progress info updates when running a task asynchronously. This example demonstrates an SFTP download.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = CreateObject("Chilkat.SFtp")

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 15000
sftp.IdleTimeoutMs = 15000

' Connect to the SFTP server.  
success = sftp.Connect("sftp.example.com",22)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' --------------------
' Download a file
' --------------------
localFilePath = "c:/temp/hamlet.xml"
remoteFilePath = "subdir1/subdir2/hamlet.xml"

' Call the async version of the DownloadFileByName method to return a task object.
' The task object is loaded, but is in the Inert state -- meaning it is
' not yet scheduled to run on Chilkat's background thread pool.
' task is a Chilkat.Task
Set task = sftp.DownloadFileByNameAsync(remoteFilePath,localFilePath)
If (sftp.LastMethodSuccess = 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Before starting the task, tell it to keep an in-memory log of what would've been
' ProgressInfo callbacks.
task.KeepProgressLog = 1

' Schedule the task for running on the thread pool.  This changes the task's state
' from Inert to Live.
success = task.Run()
If (success <> 1) Then
    outFile.WriteLine(task.LastErrorText)

    WScript.Quit
End If

' The application is now free to do anything else
' while the file is being downloaded.

' For this example, we'll simply sleep and periodically
' check to see if the download is finished, and report the progress
' along the way.
curPctDone = 0

Do While task.Finished <> 1

    If (task.PercentDone <> curPctDone) Then
        curPctDone = task.PercentDone
        outFile.WriteLine(curPctDone & " percent done")
    End If

    ' Check the progress info log.
    ' Emit any log entries..
    Do While (task.ProgressLogSize > 0)
        ' Get the 1st entry, emit it, and then remove it..
        name = task.ProgressInfoName(0)
        value = task.ProgressInfoValue(0)

        ' Entries reporting the received byte count will have the name "RcvByteCount"
        ' Entries reporting the current bytes-per-second will have the name "RcvBytesPerSec"

        outFile.WriteLine(name & ": " & value)
        task.RemoveProgressInfo 0
    Loop

    ' Sleep 100 ms.
    task.SleepMs 100

Loop

' Just in case there are any remaining entries...
Do While (task.ProgressLogSize > 0)
    ' Get the 1st entry, emit it, and then remove it..
    name = task.ProgressInfoName(0)
    value = task.ProgressInfoValue(0)
    outFile.WriteLine(name & ": " & value)
    task.RemoveProgressInfo 0
Loop

' A finished task could be one that was canceled, aborted, or truly finished.  

' If the task was "canceled", it was canceled prior to actually starting.  This could
' happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
' background thread pool scheduler.  

' If the task was "aborted", it indicates that it was canceled while running in a background thread.  
' The ResultErrorText will likely indicate that the task was aborted.

' If the task "completed", then it ran to completion, but the actual success/failure of the method
' is determined by the result obtained via a GetResult* method.  (A "completed" task will
' have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
' been aborted or canceled:
If (task.StatusInt <> 7) Then
    outFile.WriteLine("Task did not complete.")
    outFile.WriteLine("task status: " & task.Status)

    WScript.Quit
End If

' The DownloadFileByName method returns a boolean.  Therefore, after the task is finished,
' we can get the boolean result by calling GetResultBool.  This is the return value had
' we called DownloadFileByName synchronously.
success = task.GetResultBool()
If (success <> 1) Then
    ' The task's ResultErrorText contains what would have been in the LastErrorText property had
    ' the DownloadFileByName method been called synchronously.
    outFile.WriteLine(task.ResultErrorText)
Else
    outFile.WriteLine("File downloaded asynchronously.")
End If


outFile.Close