VBScript

Get ETK Public Key (api-acpt.ehealth.fgov.be)

See more Belgian eHealth Platform Examples

The following URL returns JSON, which contains a PKCS7 signed data:

https://api-acpt.ehealth.fgov.be/etee/v1/etks?identifier=12345678901&type=SSIN

This example extracts the signed data, validates it, and then extracts the public key from the certificate (obtained from signed content in the PKCS7)

Note: The URL above uses "12345678901" which is not valid. You should replace it with a valid number.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

jsonStr = http.QuickGetStr("https://api-acpt.ehealth.fgov.be/etee/v1/etks?identifier=12345678901&type=SSIN")
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(jsonStr)

' The JSON contains something like this:

' [
'     {
'         "key": {
'             "applicationIdentifier": "",
'             "ssin": "12345678901"
'         },
'         "value": "MIAGCSq....AAAAAAAA=="
'     }
' ]

' Note: The above is a JSON array (not a JSON object)
' It should be loaded into a Chilkat JSON array.
set jarr = CreateObject("Chilkat.JsonArray")
success = jarr.Load(jsonStr)
If (success = 0) Then
    outFile.WriteLine("Failed to load JSON.")
    WScript.Quit
End If

' json is a Chilkat.JsonObject
Set json = jarr.ObjectAt(0)
set bdPkcs7 = CreateObject("Chilkat.BinData")
success = bdPkcs7.AppendEncoded(json.StringOf("value"),"base64")

' Let's verify the PKCS7, and then examine the signing cert,
' and get the signing cert's public key.
set crypt = CreateObject("Chilkat.Crypt2")

' Validate the signedData PKCS7, and replace the contents of bdPkcs7 with the extracted signed content.
success = crypt.OpaqueVerifyBd(bdPkcs7)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' The signed content is the DER of a certificate.
' In other words, bdPkcs7 now contains a certificate.
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadFromBd(bdPkcs7)
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Show some certificate information:
outFile.WriteLine("Subject: " & cert.SubjectDN)
outFile.WriteLine("Serial: " & cert.SerialNumber)
outFile.WriteLine("Issuer: " & cert.IssuerDN)

' Let's get the cert's public key...
set pubKey = CreateObject("Chilkat.PublicKey")
success = cert.GetPublicKey(pubKey)

' OK, you now have the public key and can do whatever is needed..
outFile.WriteLine(pubKey.KeyType)
outFile.WriteLine(pubKey.KeySize)

outFile.Close