VBScript
AI Ask with Multiple Tool Function Callbacks

This example demonstrates asking a two-part question that should cause the AI to respond with two tool call requests.
Chilkat VBScript Downloads

VBScript
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' ----------------------------------------------------------------------------------
' The Javascript file loaded here is shown at the bottom of this page.
' -----------------------------------------------------------------------------------

' Load JavaScript containing the tool functions.
set sbJs = CreateObject("Chilkat.StringBuilder")
success = sbJs.LoadFile("qa_data/js_tools/toolset_6.js","utf-8")
If (success = 0) Then
    outFile.WriteLine(sbJs.LastErrorText)
    WScript.Quit
End If

set ai = CreateObject("Chilkat.Ai")

' Register the tools that will be made available to the AI.
evalOnly = 0
allowAllKeyword = 1
success = ai.RegisterJsTools(sbJs,evalOnly,allowAllKeyword)

' The provider can be "openai", "google", "claude", "grok", "mistral", "custom", etc.
ai.Provider = "openai"
' Use your provider's API key.
ai.ApiKey = "MY_API_KEY"
' Choose a model.
ai.Model = "gpt-5-mini"

' Tool function calling must always occur within a conversation.
conversation_name = "example_convo"
sysMessage = "You are a helpful assistant"
devMessage = "Respond with markdown"
success = ai.NewConvo(conversation_name,sysMessage,devMessage)

' Provide inputs
success = ai.InputAddText("What is my horoscope? I am an Aquarius.  Also, what's the weather in Chicago?")

' Send inputs, tool functions, etc. and ask for a "text" response.
' If the AI responds with tool calls, Chilkat automatically handles them by calling your JavaScript
' tool functions as directed by the AI, and sending results back to the AI until the final
' response is received.
success = ai.Ask("text")
If (success = 0) Then
    outFile.WriteLine(ai.LastErrorText)
    WScript.Quit
End If

' Get the AI response.
set sbResponse = CreateObject("Chilkat.StringBuilder")
success = ai.GetOutputTextSb(sbResponse)
outFile.WriteLine(sbResponse.GetAsString())

outFile.Close