(VBScript) AES XTS Mode

Demonstrates the AES-XTS mode of operation.

Note: This example requires Chilkat v9.5.0.91 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Here we have a sample from CAVS validatition data:

' COUNT = 301
' DataUnitLen = 200
' Key = 
' 394c97881abd989d29c703e48a72b397
' a7acf51b59649eeea9b33274d8541df4
' i = 4b15c684a152d485fe9937d39b168c29
' PT = 2f3b9dcfbae729583b1d1ffdd16bb6fe2757329435662a78f0
' CT = f3473802e38a3ffef4d4fb8e6aa266ebde553a64528a06463e

' Note: The above sample requires an AES-XTS implementation that fully supports ciphertext-stealing
' because the data to be encrypted is not an even multiple of the AES block size (i.e. not a multiple of 16 bytes).
' Chilkat fully supports AES-XTS with ciphertext stealing.
' (i.e. Chilkat implements XEX-based tweaked-codebook mode with ciphertext stealing (XTS))

key = "394c97881abd989d29c703e48a72b397"
tweakKey = "a7acf51b59649eeea9b33274d8541df4"
dataUnit = "4b15c684a152d485fe9937d39b168c29"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")
success = bd.AppendEncoded("2f3b9dcfbae729583b1d1ffdd16bb6fe2757329435662a78f0","hex")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "xts"
crypt.KeyLength = 128

crypt.SetEncodedKey key,"hex"
crypt.XtsSetEncodedTweakKey tweakKey,"hex"
crypt.XtsSetEncodedTweakValue dataUnit,"hex"

' In-place encrypt the contents of bd.
success = crypt.EncryptBd(bd)

outFile.WriteLine("CT = " & bd.GetEncoded("hexlower"))

' Decrypt to revert back to the unencrypted content:
success = crypt.DecryptBd(bd)

outFile.WriteLine("PT = " & bd.GetEncoded("hexlower"))

' Output:
' CT = f3473802e38a3ffef4d4fb8e6aa266ebde553a64528a06463e
' PT = 2f3b9dcfbae729583b1d1ffdd16bb6fe2757329435662a78f0

outFile.Close