(VBScript) AES Encrypt String (utf-8 byte representation) and return Base64

Demonstrates how to AES encrypt the utf-8 byte representation of a string and return in base64 format.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 256
crypt.Charset = "utf-8"
crypt.EncodingMode = "base64"

ivHex = "000102030405060708090A0B0C0D0E0F"
crypt.SetEncodedIV ivHex,"hex"
keyHex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
crypt.SetEncodedKey keyHex,"hex"

encryptedStr = crypt.EncryptStringENC("This is the original string")
outFile.WriteLine(encryptedStr)

' Let's say we want to URL encode the base64 string..
crypt.CryptAlgorithm = "none"
crypt.EncodingMode = "url"
urlEncoded = crypt.EncryptStringENC(encryptedStr)
outFile.WriteLine(urlEncoded)

' Sample output:

'  q3fmgEqjqa9o//ZS6aPuh4Wtbrrxx/WOIQSKeVnesZg=
'  q3fmgEqjqa9o%2F%2FZS6aPuh4Wtbrrxx%2FWOIQSKeVnesZg%3D

' -------------------------------------------------------------------
' Now let's do the reverse...
' 

' We start with a string that is the binary encrypted data, base64 encoded, and then URL encoded.
encBase64Url = "q3fmgEqjqa9o%2F%2FZS6aPuh4Wtbrrxx%2FWOIQSKeVnesZg%3D"

' We'll use the same crypt object.  If using a new instance of the crypt object,
' make sure *all* settings are identical:  the algorithm, cipher mode, key length, charset, encoding mode, IV, and secret key.

' Decode from URL...
crypt.CryptAlgorithm = "none"
crypt.EncodingMode = "url"
encBase64 = crypt.DecryptStringENC(urlEncoded)
outFile.WriteLine(encBase64)

' Now decrypt...
crypt.CryptAlgorithm = "aes"
crypt.EncodingMode = "base64"
originalStr = crypt.DecryptStringENC(encBase64)
outFile.WriteLine(originalStr)

outFile.Close