(VBScript) AES-CMAC

Demonstrates using the AES-CMAC algorithm, which is a keyed hash function similar to HMAC and Poly1305.

Note: Chilkat added AES-CMAC in version 9.5.0.95.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

' Set the MAC algorithm to AES-CMAC
crypt.MacAlgorithm = "aes-cmac"

' AES-CMAC always uses a 16-byte (128-bit) MAC key.
keyHex = "2b7e151628aed2a6abf7158809cf4f3c"
success = crypt.SetMacKeyEncoded(keyHex,"hex")

' Let's compute the AES-CMAC for the test vector at https://www.rfc-editor.org/rfc/rfc4493#appendix-A
' Here we have 64 bytes in hex representation.
messageBytes = "6bc1bee22e409f96e93d7e117393172aae2d8a571e03ac9c9eb76fac45af8e5130c81c46a35ce411e5fbc1191a0a52eff69f2445df4f9b17ad2b417be66c3710"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")
success = bd.AppendEncoded(messageBytes,"hex")

' Compute the AES-CMAC for the bytes contained in bd and return the AES-CMAC in hex representation.
crypt.EncodingMode = "hex_lower"
cmac = crypt.MacBdENC(bd)
outFile.WriteLine(cmac)
' Output should be: 51f0bebf7e3b9d92fc49741779363cfe

' Now do the same for a string:
plainText = "'Twas brillig, and the slithy toves" & vbLf & "Did gyre and gimble in the wabe:" & vbLf & "All mimsy were the borogoves," & vbLf & "And the mome raths outgrabe."
encTag = crypt.MacStringENC(plainText)
outFile.WriteLine(encTag)

' Output should be: 4fca1fcbd265048d247f99ab57fa3ceb

outFile.Close