(VBScript) AES and CHACHA20 Encrypt/Decrypt Text

Demonstrates the use of the new EncryptSb and DecryptSb methods introduced in Chilkat v9.5.0.67 to encrypt/decrypt the contents of StringBuilder objects.

Note: This example requires Chilkat v9.5.0.67 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First build a string to be encrypted
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sb = CreateObject("Chilkat.StringBuilder")
i = 1
Do While i < 10
    success = sb.AppendInt(i)
    success = sb.Append(" the quick brown fox jumped over the lazy dog." & vbCrLf)
    i = i + 1
Loop

outFile.WriteLine(sb.GetAsString())

' The string to be encrypted looks like this:

' 1 the quick brown fox jumped over the lazy dog.
' 2 the quick brown fox jumped over the lazy dog.
' 3 the quick brown fox jumped over the lazy dog.
' 4 the quick brown fox jumped over the lazy dog.
' 5 the quick brown fox jumped over the lazy dog.
' 6 the quick brown fox jumped over the lazy dog.
' ...

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

' Specify the encryption to be used.
' First we'll do AES-128 CBC
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

ivHex = "000102030405060708090A0B0C0D0E0F"
crypt.SetEncodedIV ivHex,"hex"

keyHex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
crypt.SetEncodedKey keyHex,"hex"

' When EncryptSb is called, the contents of the source (sb)
' remains unmodified.  The encrypted bytes are written into bdEncrypted.
' If bdEncrypted already contained data, it is replaced with the encrypted bytes.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdEncrypted = CreateObject("Chilkat.BinData")
success = crypt.EncryptSb(sb,bdEncrypted)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Examine the encrypted bytes:
outFile.WriteLine(bdEncrypted.GetEncoded("base64_mime"))

' Sample encrypted data:

' 0DdNZ22ckMMJBiaKhAu3wUEfh16XW356NIUsDmNs/xwbHe/p1201OmpfzwXwKktkAefu2pckrBgC
' df+1w8lRo+KAy5n5wlAgMGM/UrsVJsp0BmDPk1vaxKrmrGpSXOVCQs1n2+0atIs5YLiOG+Va3+Mi
' EQNb4YK7bNMmvt0++irBxTiGnkx/RncfKwgkbBUpl2x7yV13MW6lapDT6Md0DKAMsTXFJYGeIdEf
' g2uxDDQzI5gUOUHTMrXQ8paD/K76KKB9Jpp/kAM9z8g/d8KUmuphA7KI64d38xsgOmcITlbhlCQ2
' PDkcU6RRzX0FUTUSMgQukhy0jkLZEjHX9poKJD+iJTOkcQUC3OqR9hKhSrvIgJN4lxdR71MheOoQ
' 2wmvRdq+agTWWh333Vmb6J6yDV79aSpnqEDrA8Ks7Xzciol0gve91+JtVJlJKjWwEzWEU8GxF7Q8
' eaWI70lsC5nTLGcbqgKu6gzkzHlHyHaE2FAQA/d5I2dvfsAYUQCza0Zdyw8mmTtHhlP2Tfxj1uPv
' H4Q7BGuKnx3SWT2CnpbX4091w7KzLAztrbFBo/Tf9w8ZpgTK9k1ryfW9/xnk6rW6iQ==

' Decrypt to restore back to the original:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbOriginal = CreateObject("Chilkat.StringBuilder")
success = crypt.DecryptSb(bdEncrypted,sbOriginal)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Examine the original data:
outFile.WriteLine(sbOriginal.GetAsString())

' ----------------------------------------------------------------------------------
' To do chacha20 encryption, just change the settings:

crypt.CryptAlgorithm = "chacha20"
crypt.KeyLength = 256
' The initial count is the initial block counter for the chacha20 algorithm.
' It can be any integer, but must be set to the same when decrypting.
crypt.InitialCount = 22

' EncryptSb completely replaces the contents of bdEncrypted.
success = crypt.EncryptSb(sb,bdEncrypted)

' However.. DecryptSb appends the decrypted text to whatever may
' have already existed within sbOriginal.
success = crypt.DecryptSb(bdEncrypted,sbOriginal)

outFile.WriteLine("----")
outFile.WriteLine("The original data should be here twice.  Once from the AES decrypt, and again from the chacha20 decrypt.")
outFile.WriteLine(sbOriginal.GetAsString())
outFile.WriteLine("Success.")

outFile.Close