(VBScript) Example for both AES-128 and ChaCha20 to Encrypt Binary Data

Demonstrates the use of the new EncryptBd and DecryptBd methods introduced in Chilkat v9.5.0.67 to encrypt/decrypt binary bytes.

Note: This example requires Chilkat v9.5.0.67 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load a small JPG file to be encrypted/decrypted.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set jpgBytes = CreateObject("Chilkat.BinData")
success = jpgBytes.LoadFile("qa_data/jpg/starfish.jpg")
If (success <> 1) Then
    outFile.WriteLine("Failed to load JPG file.")
    WScript.Quit
End If

' Show the unencrypted JPG bytes in Base64 format.
' (The "base64_mime" encoding was added in Chilkat v9.5.0.67.
' The "base64" encoding emits a single line of base64, whereas
' "base64_mime" will emit multi-line base64 as it would appear
' in MIME.)
outFile.WriteLine(jpgBytes.GetEncoded("base64_mime"))

' Sample base64_mime JPG data:

' 	/9j/4AAQSkZJRgABAgEASABIAAD/7Q18UGhvdG9zaG9wIDMuMAA4QklNA+0AAAAAABAASAAAAAEA
' 	AQBIAAAAAQABOEJJTQPzAAAAAAAIAAAAAAAAAAE4QklNBAoAAAAAAAEAADhCSU0nEAAAAAAACgAB
' 	AAAAAAAAAAI4QklNA/UAAAAAAEgAL2ZmAAEAbGZmAAYAAAAAAAEAL2ZmAAEAoZmaAAYAAAAAAAEA
' 	MgAAAAEAWgAAAAYAAAAAAAEANQAAAAEALQAAAAYAAAAAAAE4QklNBBQAAAAAAAQAAAABOEJJTQQM
' 	...

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

' Specify the encryption to be used.
' First we'll do AES-128 CBC
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

ivHex = "000102030405060708090A0B0C0D0E0F"
crypt.SetEncodedIV ivHex,"hex"

keyHex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
crypt.SetEncodedKey keyHex,"hex"

' Do the in-place 128-bit AES CBC encryption.
' The contents of jpgBytes are replaced with the encrypted bytes.
success = crypt.EncryptBd(jpgBytes)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Examine the JPG bytes again.  The bytes should be different because they are encrypted:
outFile.WriteLine(jpgBytes.GetEncoded("base64_mime"))

' Sample base64_mime encrypted JPG data:

' 	sbz0babt1WCkQf5xKMdg/baZAcUBO5GVUUDF2BjVqmd+HrqKN+t6hAcqakL/bdo0q9hYmow0Tp1e
' 	AQ9V9DOiifQUZqWVkR+kL/c45bq8JGFDvgNl0djPt+yYhV789IB/fPH0upx+/ad++WNOlv1IxGMr
' 	Y1x1oERU/IsiEzafUJdI4kZ6FQo2IPGMF/Rm1h79I7hP1yYUFxvJyz+PzaySAUH1nLsNHyDVY5VY
' 	O90aH3steRSYbz8C8UF9wQ3qqEIXQNnnixvoNDnmHyY39VoVBI5F6rnPwYDfAk2t8tmuryFqvwAu
' 	...

' Decrypt to restore back to the original:
success = crypt.DecryptBd(jpgBytes)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(jpgBytes.GetEncoded("base64_mime"))

' 	/9j/4AAQSkZJRgABAgEASABIAAD/7Q18UGhvdG9zaG9wIDMuMAA4QklNA+0AAAAAABAASAAAAAEA
' 	AQBIAAAAAQABOEJJTQPzAAAAAAAIAAAAAAAAAAE4QklNBAoAAAAAAAEAADhCSU0nEAAAAAAACgAB
' 	AAAAAAAAAAI4QklNA/UAAAAAAEgAL2ZmAAEAbGZmAAYAAAAAAAEAL2ZmAAEAoZmaAAYAAAAAAAEA
' 	MgAAAAEAWgAAAAYAAAAAAAEANQAAAAEALQAAAAYAAAAAAAE4QklNBBQAAAAAAAQAAAABOEJJTQQM
' 	...

' ----------------------------------------------------------------------------------
' To do chacha20 encryption, just change the settings:

crypt.CryptAlgorithm = "chacha20"
crypt.KeyLength = 256
' The initial count is the initial block counter for the chacha20 algorithm.
' It can be any integer, but must be set to the same when decrypting.
crypt.InitialCount = 22

success = crypt.EncryptBd(jpgBytes)
' jpgBytes now contains chacha20 encrypted bytes.

success = crypt.DecryptBd(jpgBytes)
' jpgBytes is now restored back to the original unencrypted by bytes.

' Save the bytes to a file..
success = jpgBytes.WriteFile("qa_output/starfish.jpg")

outFile.WriteLine("Success.")

outFile.Close