VBScript

Get Access Token using a Pre-Created JSON Web Token

See more ABN AMRO Examples

Demonstrates how to get an access token using a pre-created JSON Web Token (JWT). VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' We're going to duplicate this CURL statement:
' curl -X POST https://api-sandbox.abnamro.com/v1/oauth/token \
' -H "Content-Type: application/x-www-form-urlencoded" \
' -H "API-Key: xxxxxx" \
' -d 'client_assertion_type=urn:ietf:params:oauth:client-assertion-type:jwt-bearer&grant_type=client_credentials&client_assertion=eyJhbGciOiJSUzI1NiIsInR5cCI6IkpXVCJ9.eyJzdWIiOiJ4eHh4eHgiLCJleHAiOiIxNDk5OTQ3NjY4IiwiaXNzIjoibWUiLCJhdWQiOiJodHRwczovL2F1dGgtc2FuZGJveC5hYm5hbXJvLmNvbS9vYXV0aC90b2tlbiJ9.jGwHKG_YjgKpR8NPpaLu6nJ97obeP2vcxg6fOWBKdJ0&scope=tikkie'

' Load our pre-creaed private key PEM file.
' Note: Please share your public key along with your app name and developer email id at api.support@nl.abnamro.com. 
' Token generation will not work unless public key is associated with your app.
set privkey = CreateObject("Chilkat.PrivateKey")

success = privkey.LoadPemFile("qa_data/pem/abnAmroPrivateKey.pem")
If (success = 0) Then
    outFile.WriteLine(privkey.LastErrorText)
    WScript.Quit
End If

' Create the JWT.
set jwt = CreateObject("Chilkat.Jwt")

' Create the header:
' {
'     "typ": "JWT",
'     "alg": "RS256"
' }
set jsonHeader = CreateObject("Chilkat.JsonObject")
success = jsonHeader.UpdateString("typ","JWT")
success = jsonHeader.UpdateString("alg","RS256")

' Create the payload:
' {
'     "nbf": 1499947668,
'     "exp": 1499948668,
'     "iss": "me",
'     "sub": "anApiKey",
'     "aud": "https://auth-sandbox.abnamro.com/oauth/token"
' }
set jsonPayload = CreateObject("Chilkat.JsonObject")

curDateTime = jwt.GenNumericDate(0)

' Set the "not process before" timestamp to now.
success = jsonPayload.AddIntAt(-1,"nbf",curDateTime)

' Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = jsonPayload.AddIntAt(-1,"exp",curDateTime + 3600)

success = jsonPayload.UpdateString("iss","me")
success = jsonPayload.UpdateString("sub","anApiKey")
success = jsonPayload.UpdateString("aud","https://auth-sandbox.abnamro.com/oauth/token")

' Produce the smallest possible JWT:
jwt.AutoCompact = 1

jwtStr = jwt.CreateJwtPk(jsonHeader.Emit(),jsonPayload.Emit(),privkey)
If (jwt.LastMethodSuccess = 0) Then
    outFile.WriteLine(jwt.LastErrorText)
    WScript.Quit
End If

set http = CreateObject("Chilkat.Http")

set req = CreateObject("Chilkat.HttpRequest")
req.AddParam "client_assertion_type","urn:ietf:params:oauth:client-assertion-type:jwt-bearer"
req.AddParam "grant_type","client_credentials"
req.AddParam "client_assertion",jwtStr
req.AddParam "scope","tikkie"

req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpReq("https://api-sandbox.abnamro.com/v1/oauth/token",req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

If (resp.StatusCode <> 200) Then
    outFile.WriteLine(resp.BodyStr)
    WScript.Quit
End If

' Get the JSON result:
' {
'     "access_token": "{your access token}",
'     "expires_in": "{duration of validity in seconds}",
'     "scope": "{scope(s) for which the access token is valid}",
'     "token_type": "{it is always Bearer}"
' }
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(resp.BodyStr)
outFile.WriteLine("access_token: " & json.StringOf("access_token"))
outFile.WriteLine("token_type: " & json.StringOf("token_type"))
outFile.WriteLine("expires_in: " & json.StringOf("expires_in"))
outFile.WriteLine("scope: " & json.StringOf("scope"))

outFile.Close