VBScript

X.com OAuth 2.0 Refresh Access Token

See more X Examples

Demonstrates how to get an X.com OAuth2 access token from a desktop application or script. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/x.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load x.json")
    WScript.Quit
End If

' The access token JSON looks something like this:

' {
'   "token_type": "bearer",
'   "expires_in": 7200,
'   "access_token": "VmNDLVZiYUZwejY5Mkx3RblFTmo3ek1leTRGclMuZFVOUTVUTWpNbVZKb1N5OjE3NDAxNjk4MDVxNTE6MToxOaF0OjE",
'   "scope": "block.read follows.read offline.access tweet.write block.write like.write like.read users.read tweet.read follows.write",
'   "refresh_token": "eThOWVVFSTRqdVp3QTFndGsxM2ZGZmFyNWVrU0phM1JKbGdrbGNWRGJzb1loOjE3NDAwMjk4MDUxNTI6MTowOnJ0OjE"
' }

set oauth2 = CreateObject("Chilkat.OAuth2")

oauth2.TokenEndpoint = "https://api.x.com/2/oauth2/token"

' Replace this with your actual X.com OAuth2 Client ID and Client Secret
oauth2.ClientId = "OAUTH2_CLIENT_ID"
oauth2.ClientSecret = "OAUTH2_CLIENT_SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

' Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> 1) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' Load the access token response into the json object 
success = jsonToken.Load(oauth2.AccessTokenResponse)

' If an "expires_on" member does not exist, then add the JSON member by
' getting the current system date/time and adding the "expires_in" seconds.
' This way we'll know when the token expires.
If (jsonToken.HasMember("expires_on") = 0) Then
    set dtExpire = CreateObject("Chilkat.CkDateTime")
    success = dtExpire.SetFromCurrentSystemTime()
    success = dtExpire.AddSeconds(jsonToken.IntOf("expires_in"))
    success = jsonToken.AppendString("expires_on",dtExpire.GetAsUnixTimeStr(0))
End If

' Save the new JSON access token response to a file.
' The access + refresh tokens contained in this JSON will be needed for the next refresh.
set sbJson = CreateObject("Chilkat.StringBuilder")
jsonToken.EmitCompact = 0
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/x.json","utf-8",0)

outFile.WriteLine("OAuth2 authorization granted!")
outFile.WriteLine("New Access Token = " & oauth2.AccessToken)

outFile.Close