(VBScript) X.com App only authentication and OAuth 2.0 Bearer Token

See more X Examples

This allows you to issue authenticated requests on behalf of the application itself (as opposed to on behalf of a specific user). You don’t have the context of an authenticated user and this means that any request to API for endpoints that require user context, such as posting Tweets, will not work.

Your app will be able to, for example:

• Pull user timelines;
• Access friends and followers of any account;
• Access lists resources;
• Search in Tweets;

And it will not be able to:

• Post Tweets or other resources;
• Connect to Streaming endpoints;
• Search for users;
• Use any geo endpoint;
• Access Direct Messages or account credentials;

Note: This example requires Chilkat v11.0.0 or greater.

For more information, see https://docs.x.com/resources/fundamentals/authentication/oauth-2-0/application-only

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Update these values with your consumer key and secret (also known as API Key and API Key Secret).
consumerKey = "X_CONSUMER_KEY"
consumerSecret = "X_CONSUMER_SECRET"

set http = CreateObject("Chilkat.Http")

http.BasicAuth = 1
http.Login = consumerKey
http.Password = consumerSecret

set req = CreateObject("Chilkat.HttpRequest")
req.AddParam "grant_type","client_credentials"

req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpReq("https://api.x.com/oauth2/token",req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response Status Code: " & resp.StatusCode)

If (resp.StatusCode <> 200) Then
    outFile.WriteLine("Expected a 200 response status code for success.")
    outFile.WriteLine(resp.BodyStr)
    WScript.Quit
End If

' We should get a JSON response like this:

' {
'     "token_type":"bearer",
'     "access_token":"..."
' }

set json = CreateObject("Chilkat.JsonObject")
success = json.Load(resp.BodyStr)

outFile.WriteLine("Access token = " & json.StringOf("access_token"))

outFile.Close