(VB.NET UWP/WinRT) Scan for Emails with Attachments and Save Attachments to Files

Scan for emails with attachments and save attachments.

Chilkat Universal Windows Platform (UWP) / WinRT Downloads Chilkat for the Universal Windows Platform (UWP)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As New Chilkat.Imap

' Connect to an IMAP server.
' Use TLS
imap.Ssl = True
imap.Port = 993
Dim success As Boolean = Await imap.ConnectAsync("imap.someMailServer.com")
If (success <> True) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


' Login
success = Await imap.LoginAsync("myLogin","myPassword")
If (success <> True) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


' Select an IMAP mailbox
success = Await imap.SelectMailboxAsync("Inbox")
If (success <> True) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If



Dim messageSet As Chilkat.MessageSet
' We can choose to fetch UIDs or sequence numbers.
Dim fetchUids As Boolean = True

' Get the message IDs of all the emails in the mailbox
messageSet = Await imap.SearchAsync("ALL",fetchUids)
If (imap.LastMethodSuccess <> True) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


' Fetch the email headers into a bundle object:
Dim bundle As Chilkat.EmailBundle
bundle = Await imap.FetchHeadersAsync(messageSet)
If (imap.LastMethodSuccess <> True) Then

    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


' Scan for emails with attachments, and save the attachments
' to a sub-directory.
Dim i As Integer
For i = 0 To bundle.MessageCount - 1
    Dim email As Chilkat.Email
    email = bundle.GetEmail(i)

    ' Does this email have attachments?
    ' Use GetMailNumAttach because the attachments
    ' are not actually in the email object because
    ' we only downloaded headers.
    ' (Had we downloaded the full emails by
    ' calling mailman.FetchBundle, we could look
    ' at the email object's NumAttachments property.)
    Dim numAttach As Integer = imap.GetMailNumAttach(email)

    If (numAttach > 0) Then
        ' Download the entire email and save the
        ' attachments. (Remember, we 
        ' need to download the entire email because
        ' only the headers were previously downloaded.
        ' If the entire emails were downloaded by
        ' calling FetchBundle instead of FetchHeaders,
        ' this would not be necessary.

        ' The ckx-imap-uid header field is added when
        ' headers are downloaded.  This makes it possible
        ' to get the UID from the email object.
        Dim uidStr As String = email.GetHeaderField("ckx-imap-uid")
        Dim uid As Integer = Convert.toInt32(uidStr)

        Dim fullEmail As Chilkat.Email
        fullEmail = Await imap.FetchSingleAsync(uid,True)
        If (imap.LastMethodSuccess = True) Then
            success = fullEmail.SaveAllAttachments("attachmentsDir")

        End If


        Dim j As Integer
        For j = 0 To numAttach - 1
            Dim filename As String = imap.GetMailAttachFilename(email,j)
            Debug.WriteLine(filename)
        Next

    End If


Next

' Disconnect from the IMAP server.
success = Await imap.DisconnectAsync()