(VB.NET UWP/WinRT) Initialize an HTTP Request from a URL

Demonstrates how to initialize an HTTP request object from a URL.

Chilkat Universal Windows Platform (UWP) / WinRT Downloads Chilkat for the Universal Windows Platform (UWP)

Dim req As New Chilkat.HttpRequest

' Loads the HTTP request object from a URL
req.SetFromUrl("https://www.youtube.com/watch?v=fAZdTchQePc&t=45s")

' The verb will be "GET"
Debug.WriteLine("verb = " & req.HttpVerb)
' The path will be "/watch"
Debug.WriteLine("path = " & req.Path)

' The output of this loop will be
' 0) v: fAZdTchQePc
' 1) t: 45s
Dim i As Integer
Dim numParams As Integer = req.NumParams
For i = 0 To numParams - 1
    Debug.WriteLine(i & ") " & req.GetParamName(i) & ": " & req.GetParamValue(i))
Next

' View the request that would be sent if SynchronousRequest is called.
' The HTTP request will be a GET that looks like this:
' 
'     GET /watch?v=fAZdTchQePc&t=45s HTTP/1.1
'     Host: domain
' 
' Note: The HOST header will automatically get filled in with the actual domain when SynchronousRequest is called.

Debug.WriteLine(req.GenerateRequestText())

' We can add additional params
req.AddParam("artist","Richard Bona")
req.AddParam("musicType","Jazz")
req.AddParam("festival","Estival Jazz Lugano")
req.AddParam("year","2008")

' Now examine the request that would be sent
' 
'     GET /watch?v=fAZdTchQePc&t=45s&artist=Richard%20Bona&musicType=Jazz&festival=Estival%20Jazz%20Lugano&year=2008 HTTP/1.1
'     Host: domain
' 
Debug.WriteLine(req.GenerateRequestText())

' We can remove a parameter:
req.RemoveParam("t")
Debug.WriteLine(req.GenerateRequestText())

' What happens if we change the request from a GET to a POST?
req.HttpVerb = "POST"
' The request will now look like this:
' 
'    POST /watch HTTP/1.1
'    Host: domain
'    Content-Length: 93
'    
'    v=fAZdTchQePc&artist=Richard%20Bona&musicType=Jazz&festival=Estival%20Jazz%20Lugano&year=2008
' 
Debug.WriteLine(req.GenerateRequestText())


' What happens if we make it a multipart/form-data?
req.ContentType = "multipart/form-data"
' Now the POST looks like this:
'    
'    POST /watch HTTP/1.1
'    Content-Type: multipart/form-data; boundary=------------020906020106050705030807
'    Host: domain
'    Content-Length: 545
'    
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="v"
'    
'    fAZdTchQePc
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="artist"
'    
'    Richard Bona
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="musicType"
'    
'    Jazz
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="festival"
'    
'    Estival Jazz Lugano
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="year"
'    
'    2008
'    --------------020906020106050705030807--

Debug.WriteLine(req.GenerateRequestText())