(VB.NET UWP/WinRT) DSA Signature Create and Verify

Shows how to create a DSA (DSS) signature for the contents of a file. The first step is to create an SHA-1 hash of the file contents. The hash is signed using the Digital Signature Algorithm and the signature bytes are retrieved as a hex-encoded string.

The 2nd part of the example loads the signature and verifies it against the hash.

Chilkat Universal Windows Platform (UWP) / WinRT Downloads Chilkat for the Universal Windows Platform (UWP)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New Chilkat.Crypt2

crypt.EncodingMode = "hex"
crypt.HashAlgorithm = "sha-1"

' Return the SHA-1 hash of a file.  The file may be any size.
' The Chilkat Crypt component will stream the file when 
' computing the hash, keeping the memory usage constant
' and reasonable.
' The 20-byte SHA-1 hash is returned as a hex-encoded string.
Dim hashStr As String = Await crypt.HashFileENCAsync("hamlet.xml")


Dim dsa As New Chilkat.Dsa

' Load a DSA private key from a PEM file.  Chilkat DSA
' provides the ability to load and save DSA public and private
' keys from encrypted or non-encrypted PEM or DER.
' The LoadText method is for convenience only.  You may
' use any means to load the contents of a PEM file into
' a string.
Dim pemPrivateKey As String
pemPrivateKey = dsa.LoadText("dsa_priv.pem")
Dim success As Boolean = dsa.FromPem(pemPrivateKey)
If (success <> True) Then
    Debug.WriteLine(dsa.LastErrorText)
    Exit Sub
End If


' You may optionally verify the key to ensure that it is a valid
' DSA key.
success = dsa.VerifyKey()
If (success <> True) Then
    Debug.WriteLine(dsa.LastErrorText)
    Exit Sub
End If


' Load the hash to be signed into the DSA object:
success = dsa.SetEncodedHash("hex",hashStr)
If (success <> True) Then
    Debug.WriteLine(dsa.LastErrorText)
    Exit Sub
End If


' Now that the DSA object contains both the private key and hash,
' it is ready to create the signature:
success = dsa.SignHash()
If (success <> True) Then
    Debug.WriteLine(dsa.LastErrorText)
    Exit Sub
End If


' If SignHash is successful, the DSA object contains the
' signature.  It may be accessed as a hex or base64 encoded
' string.  (It is also possible to access directly in byte array form via
' the "Signature" property.)
Dim hexSig As String = dsa.GetEncodedSignature("hex")
Debug.WriteLine("Signature:")
Debug.WriteLine(hexSig)

' -----------------------------------------------------------
' Step 2: Verify the DSA Signature
' -----------------------------------------------------------

Dim dsa2 As New Chilkat.Dsa

' Load the DSA public key to be used for verification:
Dim pemPublicKey As String
pemPublicKey = dsa2.LoadText("dsa_pub.pem")
success = dsa2.FromPublicPem(pemPublicKey)
If (success <> True) Then
    Debug.WriteLine(dsa2.LastErrorText)
    Exit Sub
End If


' Load the hash to be verified against the signature.
success = dsa2.SetEncodedHash("hex",hashStr)
If (success <> True) Then
    Debug.WriteLine(dsa2.LastErrorText)
    Exit Sub
End If


' Load the signature:
success = dsa2.SetEncodedSignature("hex",hexSig)
If (success <> True) Then
    Debug.WriteLine(dsa2.LastErrorText)
    Exit Sub
End If


' Verify:
success = dsa2.Verify()
If (success <> True) Then
    Debug.WriteLine(dsa2.LastErrorText)
Else
    Debug.WriteLine("DSA Signature Verified!")
End If