(VB.NET) Set Entry Filepath (in output Zip) when Zipping

Demonstrates how to set the path for the file entry within the .zip to something different than the path in the filesystem.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This requires the Chilkat Zip API to have been previously unlocked.
' See Unlock Chilkat Zip for sample code.

Dim zip As New Chilkat.Zip

Dim success As Boolean = zip.NewZip("qa_output/zipA.zip")

' When an absolute filepath is passed to AppendOneFileOrDir, the path within the .zip
' will be one of two values:  (1) just the filename part if saveExtraPath is False,
' or (2) the full absolute path, but made relative, if saveExtraPath is True.
' (For example, "c:/ck2000/appData/UnitTest/qa_data/hamlet.xml" made relative is 
' "ck2000/appData/UnitTest/qa_data/hamlet.xml")
Dim saveExtraPath As Boolean = False
success = zip.AppendOneFileOrDir("c:/ck2000/appData/UnitTest/qa_data/hamlet.xml",saveExtraPath)
If (success <> True) Then
    Debug.WriteLine(zip.LastErrorText)
    Exit Sub
End If


' When a relative path is passed to AppendOneFileOrDir, then saveExtraPath does not apply.
' For example, assume our current working directory is "c:/ck2000/appData/UnitTest".  The following
' call to AppendOneFileOrDir creates an entry with the filepath "qa_data/hamlet.xml".
success = zip.AppendOneFileOrDir("qa_data/hamlet.xml",saveExtraPath)
If (success <> True) Then
    Debug.WriteLine(zip.LastErrorText)
    Exit Sub
End If


' Examine the entries
Dim numEntries As Integer = zip.NumEntries
Dim i As Integer = 0
While i < numEntries
    Dim e As Chilkat.ZipEntry = zip.GetEntryByIndex(i)
    Debug.WriteLine(i & ": " & e.FileName)

    i = i + 1
End While

' The output so far is:

' 	0: hamlet.xml
' 	1: qa_data/hamlet.xml

' If we write the .zip as-is, then the zip will have two entries
' with the filepaths as shown above.

' This writes "qa_output/zipA.zip"
success = zip.WriteZip()

' Now change the entry filepaths to whatever is desired.
Dim entry As Chilkat.ZipEntry = zip.GetEntryByName("hamlet.xml")
If (zip.LastMethodSuccess = False) Then
    Debug.WriteLine("entry not found")
    Exit Sub
End If


entry.FileName = "Shakespeare/Claudius1.xml"


entry = zip.GetEntryByName("qa_data/hamlet.xml")
If (zip.LastMethodSuccess = False) Then
    Debug.WriteLine("entry not found")
    Exit Sub
End If


entry.FileName = "Shakespeare/Claudius2.xml"


' Change the name of the .zip to be written and write again:
zip.FileName = "qa_output/zipB.zip"
success = zip.WriteZipAndClose()
If (success <> True) Then
    Debug.WriteLine(zip.LastErrorText)
Else
    Debug.WriteLine("Zip created!")
End If


' Examine both zipA.zip and zipB.zip using 7zip (or another tool) to see the differences.