(VB.NET) Wasabi File Streaming Upload

See more Wasabi Examples

Demonstrates how to do a streaming upload from a file to the Wasabi storage service. The AWS authorization presents some difficulties when the REST request body is to be streamed from a file (or from some other source). The issue is that the SHA-256 hash of the file data must be calculated. There are only two possible ways to do this: (1) stream the file into memory in its entirety and calculate the SHA-256 hash prior to uploading, or (2) pre-calculate the SHA-256 in a streaming fashion, and then provide it to the AWS authentication object.

If the application does NOT pre-compute the SHA-256, then Chilkat (internally) is forced to stream into memory, calculate the SHA-256, and then upload from the in-memory copy of the file.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.


' This first part is optional.  AWS authentication requires
' the SHA-256 hash of the request body (i.e. the contents of the file
' to be uploaded).  We can choose to pre-calculate the SHA-256 in a streaming fashion
' and then provide it to the authenticator object.  This way, if the file is
' extremely large, it never needs to completely reside in memory.
Dim crypt As New Chilkat.Crypt2
' ----------------------------------------------------
' Important: Wasabi requires a lowercase hex format.
' ----------------------------------------------------
crypt.EncodingMode = "hex-lower"
crypt.HashAlgorithm = "sha-256"
Dim fileToUploadPath As String = "qa_data/xml/hamlet.xml"
Dim hashStr As String = crypt.HashFileENC(fileToUploadPath)

Dim rest As New Chilkat.Rest

' Connect to the Amazon AWS REST server.
Dim bTls As Boolean = True
Dim port As Integer = 443
Dim bAutoReconnect As Boolean = True
' This example will demonstrate uploading to a bucket in the eu-west-2 region
Dim success As Boolean = rest.Connect("s3.eu-west-2.wasabisys.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
Dim authAws As New Chilkat.AuthAws
authAws.AccessKey = "access-key"
authAws.SecretKey = "secret-key"
authAws.ServiceName = "s3"
' Provide the pre-computed SHA-256 here:
authAws.PrecomputedSha256 = hashStr

success = rest.SetAuthAws(authAws)

rest.AddHeader("Expect","100-continue")
rest.AddHeader("Content-Type","application/xml")

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkat100".
rest.Host = "chilkat100.s3.eu-west-2.wasabisys.com"

Dim fileStream As New Chilkat.Stream
fileStream.SourceFile = fileToUploadPath

' Upload to the Wasabi Storage service.
' If the application provided the SHA-256 hash of the file contents (as shown above)
' then file is streamed and never has to completely reside in memory.
' If the application did NOT provide the SHA-256, then Chilkat will (internally) 
' load the entire file into memory, calculate the SHA-256, and then upload.
Dim responseStr As String = rest.FullRequestStream("PUT","/hamlet.xml",fileStream)
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' When successful, the Wasabi Storage service will respond with a 200 response code,
' with an XML body.  
If (rest.ResponseStatusCode = 200) Then
    Debug.WriteLine(responseStr)
    Debug.WriteLine("File uploaded.")
Else
    ' Examine the request/response to see what happened.
    Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Debug.WriteLine("response body: " & responseStr)
    Debug.WriteLine("---")
    Debug.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    Debug.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
End If