(VB.NET) Create Restricted Data Token (RDT)

See more Amazon SP-API Examples

Returns a Restricted Data Token (RDT) for one or more restricted resources that you specify.

For more information, see https://developer-docs.amazon.com/sp-api/docs/tokens-api-v2021-03-01-reference#post-tokens2021-03-01restricteddatatoken

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim authAws As New Chilkat.AuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "execute-api"
' Use the region that is correct for your needs.
authAws.Region = "eu-west-1"

Dim rest As New Chilkat.Rest
Dim bTls As Boolean = True
Dim port As Integer = 443
Dim bAutoReconnect As Boolean = True
' The sandbox endpoint (sandbox.sellingpartnerapi-eu.amazon.com) fails.
' Use the production endpoint and see the note below.
Dim success As Boolean = rest.Connect("sellingpartnerapi-eu.amazon.com",port,bTls,bAutoReconnect)
If (success = False) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


success = rest.SetAuthAws(authAws)

' Load the previously obtained LWA access token.
' See Fetch SP-API LWA Access Token
Dim jsonToken As New Chilkat.JsonObject
success = jsonToken.LoadFile("qa_data/tokens/sp_api_lwa_token.json")
If (success = False) Then
    Debug.WriteLine("Failed to load LWA access token.")
    Exit Sub
End If


' Add the x-amz-access-token request header.
Dim lwa_token As String = jsonToken.StringOf("access_token")
rest.ClearAllHeaders()
rest.AddHeader("x-amz-access-token",lwa_token)


' We're going to send a POST with the following JSON body:

' {
'   "restrictedResources": [
'     {
'       "method": "GET",
'       "path": "/orders/v0/orders",
'       "dataElements": ["buyerInfo", "shippingAddress"]
'     }
'   ]
' }

' Use this online tool to generate code from sample JSON: 
' Generate Code to Create JSON

Dim json As New Chilkat.JsonObject
json.UpdateString("restrictedResources[0].method","GET")
json.UpdateString("restrictedResources[0].path","/orders/v0/orders")
json.UpdateString("restrictedResources[0].dataElements[0]","buyerInfo")
json.UpdateString("restrictedResources[0].dataElements[1]","shippingAddress")

Dim sbRequest As New Chilkat.StringBuilder
json.EmitSb(sbRequest)

Dim sbResponse As New Chilkat.StringBuilder
Dim uri As String = "/tokens/2021-03-01/restrictedDataToken"
success = rest.FullRequestSb("POST",uri,sbRequest,sbResponse)
If (success = False) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' ------------------------------------------------------------------------------------
' Note: Using the sandbox endpoint, such as sandbox.sellingpartnerapi-eu.amazon.com
' results in a response status code of 400 with the following error:
' [{"code":"InvalidInput","message":"Could not match input arguments"}]
' Getting a restricted data token seems to only work with the production endpoint.
' ------------------------------------------------------------------------------------

' Examine the response status.
Dim statusCode As Integer = rest.ResponseStatusCode
If (statusCode <> 200) Then
    Debug.WriteLine("Response status code: " & statusCode)
    Debug.WriteLine("Response status text: " & rest.ResponseStatusText)
    Debug.WriteLine("Response body: ")
    Debug.WriteLine(sbResponse.GetAsString())
    Debug.WriteLine("Failed.")
    Exit Sub
End If


Debug.WriteLine(sbResponse.GetAsString())

' If successful, gets a JSON response such as the following:

' {
'   "expiresIn": 3600,
'   "restrictedDataToken": "Atz.sprdt|AYAB.....TQ="
' }


' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

Dim jsonResp As New Chilkat.JsonObject
jsonResp.LoadSb(sbResponse)

Dim expiresIn As Integer = jsonResp.IntOf("expiresIn")
Dim restrictedDataToken As String = jsonResp.StringOf("restrictedDataToken")

' Save the RDT for subsequent use..
success = jsonResp.WriteFile("qa_data/tokens/sp_api_rdt_token.json")

Debug.WriteLine("Success!")