(VB.NET) Send Email and Put Copy in "Sent" Folder

This example demonstrates how to send an email, and then put a copy of it in the "Sent" mail folder. This is only possible if the "Sent" folder is located on the mail server and accessed via the IMAP protocol. The POP3 protocol can only access the Inbox on the mail server.

This does not work with "Sent", "Sent Items", or "Sent Messages" folders that are stored locally on your computer by an email client such as Outlook or Thunderbird. Chilkat has no ability to copy email to the local files managed by these email clients.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Boolean

' The mailman object is used for sending and receiving email.
Dim mailman As New Chilkat.MailMan

' Set the SMTP server.
mailman.SmtpHost = "smtp.my-mail-server.com"

' Set the SMTP login/password (if required)
mailman.SmtpUsername = "myUsername"
mailman.SmtpPassword = "myPassword"

' Create a new email object
Dim email As New Chilkat.Email

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo("Chilkat Admin","admin@chilkatsoft.com")
' To add more recipients, call AddTo, AddCC, or AddBcc once per recipient.


' Call SendEmail to connect to the SMTP server and send.
success = mailman.SendEmail(email)
If (success <> True) Then
    Debug.WriteLine(mailman.LastErrorText)
    Exit Sub
End If



' Some SMTP servers do not actually send the email until 
' the connection is closed.  In these cases, it is necessary to
' call CloseSmtpConnection for the mail to be  sent.  
' Most SMTP servers send the email immediately, and it is 
' not required to close the connection.  We'll close it here
' for the example:
success = mailman.CloseSmtpConnection()
If (success <> True) Then
    Debug.WriteLine("Connection to SMTP server not closed cleanly.")

End If


Debug.WriteLine("Mail Sent!")


' The mail has been sent.  Now save the email to the "Sent" folder
' on your mail server.  (Your "Sent" folder could be named something else,
' or you may store the email in any folder of your choosing.)
Dim imap As New Chilkat.Imap


' Connect to an IMAP server.
' Use TLS
imap.Ssl = True
imap.Port = 993
success = imap.Connect("imap.my-mail-server.com")
If (success <> True) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


' Login
success = imap.Login("myLogin","myPassword")
If (success <> True) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


' Upload (save) the email to the "Sent" mailbox.
success = imap.AppendMail("Sent",email)
If (success <> True) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("Email saved to the Sent folder.")

' Disconnect from the IMAP server.
success = imap.Disconnect()