(VB.NET) OAuth2 for a GMail using a JSON Service Account Key

Demonstrates how get an OAuth2 access token for GMail (Google Service Account) using a JSON private key.

After the access token is obtained, it may be used to send email. When the access token expires, a new access token needs to be obtained (using this same procedure).

Note: This is for OAuth2 using Google Service account keys.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First load the JSON key into a string.
Dim fac As New Chilkat.FileAccess
Dim jsonKey As String = fac.ReadEntireTextFile("qa_data/googleApi/ChilkatTest-ab2ecd52ef98.json","utf-8")
If (fac.LastMethodSuccess <> True) Then
    Debug.WriteLine(fac.LastErrorText)
    Exit Sub
End If


' A JSON private key should look like this:

' 	{
' 	  "type": "service_account",
' 	  "project_id": "chilkattest-1350",
' 	  "private_key_id": "fa2e36ee26986eab628b59868af8bec1d1c64c38",
' 	  "private_key": "-----BEGIN PRIVATE KEY-----\nMIIEvgIjFa...28N64N2n1E4FYzBZjSdy\n-----END PRIVATE KEY-----\n",
' 	  "client_email": "598922945226-00rb0ppfg0sndajo6bhvd4v17jtj2d3a@developer.gserviceaccount.com",
' 	  "client_id": "598922945226-00rb0ppfg0snd9jo7bhvd4v17jtj2d3a.apps.googleusercontent.com",
' 	  "auth_uri": "https://accounts.google.com/o/oauth2/auth",
' 	  "token_uri": "https://accounts.google.com/o/oauth2/token",
' 	  "auth_provider_x509_cert_url": "https://www.googleapis.com/oauth2/v1/certs",
' 	  "client_x509_cert_url": "https://www.googleapis.com/robot/v1/metadata/x509/598922945226-00rb0ppfg0sndajo6bhvd4v17jtj2d3a%40developer.gserviceaccount.com"
' 	}


Dim gAuth As New Chilkat.AuthGoogle
gAuth.JsonKey = jsonKey

' Choose a scope.
gAuth.Scope = "https://mail.google.com/"

' Request an access token that is valid for this many seconds.
gAuth.ExpireNumSeconds = 3600

' If the application is requesting delegated access:
' The email address of the user for which the application is requesting delegated access,
' then set the email address here. (Otherwise leave it empty.)
gAuth.SubEmailAddress = ""

' Connect to www.googleapis.com using TLS (TLS 1.2 is the default.)
' The Chilkat socket object is used so that the connection can be established
' through proxies or an SSH tunnel if desired.
Dim tlsSock As New Chilkat.Socket
Dim success As Boolean = tlsSock.Connect("www.googleapis.com",443,True,5000)
If (success <> True) Then
    Debug.WriteLine(tlsSock.LastErrorText)
    Exit Sub
End If


' Send the request to obtain the access token.
success = gAuth.ObtainAccessToken(tlsSock)
If (success <> True) Then
    Debug.WriteLine(gAuth.LastErrorText)
    Exit Sub
End If


' Examine the access token:
Debug.WriteLine("Access Token: " & gAuth.AccessToken)

' Now that we have the access token, it may be used to send email
' while it remains valid.  Once the access token expires, a new access token 
' should be obtained using the same code as above.


' -----------------------------------------------------------------------
Dim mailman As New Chilkat.MailMan

' Set the properties for the GMail SMTP server:
mailman.SmtpHost = "smtp.gmail.com"
mailman.SmtpPort = 587
mailman.StartTLS = True

mailman.SmtpUsername = "YOUR_GOOGLE_APPS_USER_EMAIL_ADDRESS"
mailman.OAuth2AccessToken = gAuth.AccessToken

' Create a new email object
Dim email As New Chilkat.Email

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "YOUR NAME <YOUR_GOOGLE_APPS_USER_EMAIL_ADDRESS>"
success = email.AddTo("Chilkat Admin","admin@chilkatsoft.com")
' To add more recipients, call AddTo, AddCC, or AddBcc once per recipient.

' Call SendEmail to connect to the SMTP server and send.
' The connection (i.e. session) to the SMTP server remains
' open so that subsequent SendEmail calls may use the
' same connection.  
success = mailman.SendEmail(email)
If (success <> True) Then
    Debug.WriteLine(mailman.LastErrorText)
    Exit Sub
End If


' You may close the connection here.  If the connection is kept open, 
' the next call to mailman.SendEmail will continue using the already-established connection
' (and automatically re-connect if needed).
success = mailman.CloseSmtpConnection()
If (success <> True) Then
    Debug.WriteLine("Connection to SMTP server not closed cleanly.")
End If


Debug.WriteLine("Email Sent via GMail using an OAuth2 Service Account Key.")