VB.NET

SII Chile - FRMA Signature Computation and Add to XML

See more XML Digital Signatures Examples

Compute the FRMA signature of a <DA> element enclosed inside a <CAF> element of the XML to be signed. VB.NET

Dim success As Boolean = False

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Also see:  Compute the FRMT Signature and Add to XML

Dim xml As New Chilkat.Xml

' Load the unsigned XML that contains the following:

' <DTE version="1.0">
'   <Documento ID="F60T33">
'         <TED version="1.0">
'             <DD>
' 		...
'                 <CAF version="1.0">
'                     <DA>
' 			...
'                     </DA>
' 			... The FRMA will be added here ...
'                 </CAF>
'                 ...
'             </DD>
'             ... The FRMT will be added here in another example ...
'         </TED>
'   </Documento>
' </DTE>

success = xml.LoadXmlFile("qa_data/xml_dsig/sii_cl/test_0.xml")
If (success = False) Then
    Debug.WriteLine("Failed to load initial XML file.")
    Exit Sub
End If


' Get a reference to the "DA" element
Dim daXml As Chilkat.Xml = xml.FindChild("Documento|TED|DD|CAF|DA")
If (xml.LastMethodSuccess = False) Then
    Debug.WriteLine("Failed to find DA element")
    Exit Sub
End If


'  We need to get the "flattened" DA XML where:
'    - No whitespace between elements.
'    - The 5 pre-defined entities are converted.
'    - The text is encoded in the ISO-8859-1 character set (Latin-1), 
Dim sbFlattened As New Chilkat.StringBuilder
daXml.EmitCompact = True
daXml.EmitXmlDecl = False
daXml.GetXmlSb(sbFlattened)

' Compute the SHA-1 message digest of the iso-8859-1 byte representation, 
' and sign it with our RSA private key, getting the result in base64 format.

Dim privKey As New Chilkat.PrivateKey
success = privKey.LoadAnyFormatFile("qa_data/rsa/rsaPrivKey_pkcs8.pem","")
If (success = False) Then
    Debug.WriteLine(privKey.LastErrorText)
    Exit Sub
End If


Dim rsa As New Chilkat.Rsa
rsa.UsePrivateKey(privKey)

rsa.EncodingMode = "base64"
rsa.Charset = "iso-8859-1"
Dim sig As String = rsa.SignStringENC(sbFlattened.GetAsString(),"sha1")

' Add the FRMA signature element to the XML.
xml.UpdateChildContent("Documento|TED|DD|CAF|FRMA",sig)
xml.UpdateAttrAt("Documento|TED|DD|CAF|FRMA",True,"algoritmo","SHA1withRSA")



' See what we have:
xml.EmitCompact = False
xml.EmitXmlDecl = True
Debug.WriteLine(xml.GetXml())

xml.SaveXml("qa_data/xml_dsig/sii_cl/test_1.xml")