VB.NET

PDF Signature with Background Image (Seal/Stamp/etc.)

See more PDF Signatures Examples

Demonstrates how to sign a PDF with an appearance that includes a background image, such as a seal, stamp, etc.

Note: This example requires Chilkat v9.5.0.85 or greater.

VB.NET

Dim success As Boolean = False

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim pdf As New Chilkat.Pdf

' Load a PDF to be signed.
' The "hello.pdf" is available at https://chilkatsoft.com/hello.pdf
success = pdf.LoadFile("qa_data/pdf/hello.pdf")
If (success = False) Then
    Debug.WriteLine(pdf.LastErrorText)
    Exit Sub
End If


' Options for signing are specified in JSON.
Dim json As New Chilkat.JsonObject

' In most cases, the signingCertificateV2 and signingTime attributes are required.
json.UpdateInt("signingCertificateV2",1)
json.UpdateInt("signingTime",1)

' Put the signature on page 1, top left
json.UpdateInt("page",1)
json.UpdateString("appearance.y","top")
json.UpdateString("appearance.x","left")

' Use a font scale of 10.0
json.UpdateString("appearance.fontScale","10.0")

' In this example, the appearance of the digital signature will contain three lines:
' 1) The signing certificate's common name
' 2) The current date/time
' 3) Some arbitrary text.
' The keyword "cert_cn" is replaced with the Certificate's Subject Common Name.
' The keyword "current_dt" is replaced with the current date/time.
' Any number of appearance text lines can be added.
json.UpdateString("appearance.text[0]","Digitally signed by: cert_cn")
json.UpdateString("appearance.text[1]","current_dt")
json.UpdateString("appearance.text[2]","The crazy brown fox jumps over the lazy dog.")

' Load a JPG image to be shown with 30% opacity in the background.
' (the image must be in the JPG format)
' The sample university.jpb is available at https://example-code.com/images/university.jpg

Dim jpgData As New Chilkat.BinData
success = jpgData.LoadFile("qa_data/jpg/university.jpg")
If (success = False) Then
    Debug.WriteLine("Failed to load the JPG image.")
    Exit Sub
End If

success = pdf.SetSignatureJpeg(jpgData)
If (success = False) Then
    Debug.WriteLine(pdf.LastErrorText)
    Exit Sub
End If


' Specify that we want to display the JPG image in the center with 30% opacity.
json.UpdateString("appearance.image","custom-jpg")
json.UpdateString("appearance.imagePlacement","center")
json.UpdateString("appearance.imageOpacity","30")

' Load the signing certificate. (Use your own certificate.)
Dim cert As New Chilkat.Cert
success = cert.LoadPfxFile("qa_data/pfx/myPdfSigningCert.pfx","secret")
If (success = False) Then
    Debug.WriteLine(cert.LastErrorText)
    Exit Sub
End If


' Tell the pdf object to use the certificate for signing.
success = pdf.SetSigningCert(cert)
If (success = False) Then
    Debug.WriteLine(pdf.LastErrorText)
    Exit Sub
End If


success = pdf.SignPdf(json,"qa_output/hello_signed.pdf")
If (success = False) Then
    Debug.WriteLine(pdf.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("The PDF has been successfully cryptographically signed.")

' The appearance of the signature appears in Adobe Acrobat as shown below.
' The JPG is automatically scaled to the size of the signature based on the signature's font scale
' and number of text lines.
' (image:https://example-code.com/images/signature2.jpg/endImage)