VB.NET

List Files and Folders in a SharePoint Documents Library

See more SharePoint Examples

This example shows how to use Chilkat's HttpCurl class to list the files and folders in the root of a SharePoint Documents document library. In Microsoft Graph, a SharePoint document library is represented as a drive. The example demonstrates how HttpCurl automatically resolves the SharePoint site name to a site ID, finds the drive ID for the Documents library, and then retrieves the children of the library's root folder.

VB.NET

Dim success As Boolean = False

' This example lists the files and folders in the root of the SharePoint
' Documents document library.
' 
' In Microsoft Graph terminology, a SharePoint document library is represented
' as a "drive".  The default document library is commonly named "Documents".
' This example shows how HttpCurl can automatically resolve the needed values:
' 
'   site_name  ->  site_id
'   site_id    ->  document_library_id
' 
' After those values are known, the final request lists the children of the
' root folder in the Documents document library.

success = False

' --------------------------------------------------------------------------------------------------------
' Before running this example, create an Azure App Registration and grant it
' the Microsoft Graph permissions required to access SharePoint.
' 
' The application will authenticate using OAuth2 Client Credentials.
' See:
' How to Create SharePoint App Registration for OAuth 2.0 Client Credentials
' --------------------------------------------------------------------------------------------------------

' Build a JSON authentication configuration.
' HttpCurl will use this information to automatically obtain OAuth2 access tokens.
Dim jsonAuth As New Chilkat.JsonObject

' Enable secret lookup.
' 
' Instead of hard-coding sensitive values such as the client ID,
' client secret, and token endpoint, secret specification strings
' are used.  Chilkat automatically retrieves the actual values from
' Windows Credential Manager (Windows) or Apple Keychain (macOS).
' 
' See:
' Secret Specification Strings
jsonAuth.EnableSecrets = True

success = jsonAuth.UpdateString("oauth2.client_id","!!sharepoint|oauth2|client_id")
If (success = True) Then
    success = jsonAuth.UpdateString("oauth2.client_secret","!!sharepoint|oauth2|client_secret")
End If

If (success = True) Then
    success = jsonAuth.UpdateString("oauth2.token_endpoint","!!sharepoint|oauth2|token_endpoint")
End If

If (success = False) Then
    Debug.WriteLine(jsonAuth.LastErrorText)
    Exit Sub
End If


' Request Microsoft Graph permissions that were granted to the application.
jsonAuth.UpdateString("oauth2.scope","https://graph.microsoft.com/.default")

' ---------------------------------------------------------------------------------------------------

Dim curl As New Chilkat.HttpCurl

' Associate the OAuth2 configuration with HttpCurl.
' 
' When the request is executed, Chilkat automatically obtains an access token
' if needed and adds the Authorization: Bearer header to the HTTP request.
curl.SetAuth(jsonAuth)

' Define variables whose values are already known.
' 
' These variables are referenced in curl commands using
' {{variable_name}} substitution syntax.
curl.SetVar("sharepoint_hostname","example.sharepoint.com")
curl.SetVar("site_name","test")

' The final request needs a Microsoft Graph site ID.
' 
' Because the application only knows the SharePoint site name,
' define a helper function that can retrieve the site record.
' HttpCurl can execute this function automatically when it needs
' to resolve the site_id variable.
curl.AddFunction("getSite","GET https://graph.microsoft.com/v1.0/sites/root:/sites/{{site_name}}")

' Extract the "id" field from the getSite response and store it
' in the HttpCurl variable named "site_id".
curl.AddOutput("getSite","id","site_id")

' The next value needed is the drive ID for the Documents document library.
' 
' This function lists the drives, also known as document libraries,
' belonging to the SharePoint site.
curl.AddFunction("getDrives","GET https://graph.microsoft.com/v1.0/sites/{{site_id}}/drives")

' Extract the ID of the drive whose name is "Documents".
' 
' AddOutput2 searches an array in the JSON response.  In this case:
' 
'   response array: value
'   match field:    name
'   match value:    Documents
'   case-sensitive: true
'   output field:   id
'   variable name:  document_library_id
' 
' The result is that document_library_id will contain the drive ID
' for the Documents document library.
curl.AddOutput2("getDrives","value","name","Documents",True,"id","document_library_id")

' The target Microsoft Graph request:
' 
' GET https://graph.microsoft.com/v1.0/sites/{{site_id}}/drives/{{document_library_id}}/root/children
' 
' This lists the files and folders in the root folder of the Documents
' document library.
' 
' The {{site_id}} and {{document_library_id}} variables are not set directly
' by this program.  HttpCurl resolves them automatically by running the
' helper functions defined above.
Dim curlCommand As String = "GET https://graph.microsoft.com/v1.0/sites/{{site_id}}/drives/{{document_library_id}}/root/children"

' Execute the request.
' 
' HttpCurl examines the target request and determines that it requires
' both site_id and document_library_id.
' 
' The execution plan becomes:
' 
'   1) Execute getSite to obtain site_id.
'   2) Execute getDrives to obtain document_library_id.
'   3) Substitute both variables into the target request.
'   4) Execute the root/children request.
' 
' The final HTTP response returned by DoYourThing is always the response
' from the target request, which is the last step in the plan.
success = curl.DoYourThing(curlCommand)
If (success = False) Then
    Debug.WriteLine(curl.LastErrorText)
    Exit Sub
End If


' A successful Graph response should return HTTP 200.
' Any other status code typically indicates an authentication,
' permission, site lookup, or document library lookup error.
Dim statusCode As Integer = curl.StatusCode
If (statusCode <> 200) Then
    Debug.WriteLine(curl.ResponseBodyStr)
    Debug.WriteLine("status code = " & statusCode)
    Exit Sub
End If


' The response body contains a JSON array named "value".
' Each element represents one file or folder in the root of the
' Documents document library.
Dim json As New Chilkat.JsonObject
json.EmitCompact = False
curl.GetResponseJson(json)
Debug.WriteLine(json.Emit())
Debug.WriteLine("")

' Count the number of items returned in the "value" array.
' 
' This includes both files and folders.
Dim numFiles As Integer = json.SizeOfArray("value")
Debug.WriteLine("Number of files: " & numFiles)
Debug.WriteLine("")

' Iterate over the files and folders returned by Microsoft Graph
' and display selected properties for each item.
Dim i As Integer = 0
While i < numFiles
    json.I = i

    Debug.WriteLine("name: " & json.StringOf("value[i].name"))
    Debug.WriteLine("webUrl: " & json.StringOf("value[i].webUrl"))
    Debug.WriteLine("size: " & json.StringOf("value[i].size"))
    Debug.WriteLine("id: " & json.StringOf("value[i].id"))
    Debug.WriteLine("-")
    i = i + 1
End While