(VB.NET) SFTP Upload Large File in Parts

See more SFTP Examples

Demonstrates how to split a large file into N parts and then upload each part separately. This technique can be used to potentially avoid limits a SFTP server might impose on upload file size.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim sftp As New Chilkat.SFtp

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 10000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
Dim hostname As String = "sftp.example.com"
Dim port As Integer = 22
Dim success As Boolean = sftp.Connect(hostname,port)
If (success <> True) Then
    Debug.WriteLine(sftp.LastErrorText)
    Exit Sub
End If


' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> True) Then
    Debug.WriteLine(sftp.LastErrorText)
    Exit Sub
End If


' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> True) Then
    Debug.WriteLine(sftp.LastErrorText)
    Exit Sub
End If


' Open a remote file for writing on the SSH server.
' If the file already exists, it is overwritten.
' (Specify "createNew" instead of "createTruncate" to
' prevent overwriting existing files.)
Dim handle As String = sftp.OpenFile("big.zip","writeOnly","createTruncate")
If (sftp.LastMethodSuccess <> True) Then
    Debug.WriteLine(sftp.LastErrorText)
    Exit Sub
End If


' We're going to upload the local file "qa_data/zips/big.zip" (a relative local path from our current working directory)
' to the SFTP server.
Dim localFilePath As String = "qa_data/zips/big.zip"

' Rather than uploading in one shot, we'll read the local file in chunks
' and upload a chunk at a time.
Dim fac As New Chilkat.FileAccess

success = fac.OpenForRead(localFilePath)
If (success = False) Then
    sftp.CloseHandle(handle)
    Debug.WriteLine(fac.LastErrorText)
    Exit Sub
End If


' If we were to split the local file into 128K chunks, how many chunks (blocks) would
' we have, including the last partial block?
Dim blockSize As Integer = 131072
Dim numBlocks As Integer = fac.GetNumBlocks(blockSize)
Debug.WriteLine("Number of blocks = " & numBlocks)

Dim bd As New Chilkat.BinData
Dim i As Integer = 0
While i < numBlocks
    ' Read the Nth block, which gets appended to the bd.  (which means
    ' we must clear the contents of bd before the next iteration)
    success = fac.ReadBlockBd(i,blockSize,bd)
    If (success = False) Then
        sftp.CloseHandle(handle)
        Debug.WriteLine(fac.LastErrorText)
        Exit Sub
    End If


    ' Upload this block to the open remote file.
    success = sftp.WriteFileBd(handle,bd)
    If (success = False) Then
        Debug.WriteLine(sftp.LastErrorText)
        Exit Sub
    End If


    ' Clear the contents for the next iteration.
    bd.Clear()

    i = i + 1
End While

' Close the local file.
fac.FileClose()

' -----------------------------------------------------------------------------
' This is important.  You must close the handle on the server.
' Otherwise open handles will accumulate on the server until eventually a limit
' is reached and the server will fail on a call to OpenFile.
' -----------------------------------------------------------------------------

' Close the remote file handle on the server.
success = sftp.CloseHandle(handle)
If (success <> True) Then
    Debug.WriteLine(sftp.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("Success.")