(VB.NET) S3 Get Object Metadata, such as ETag

Demonstrates how to get an S3 object's metadata using a HEAD request.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

' Connect to the Amazon AWS REST server in the desired region.
' In this case we connect to S3 in the "us-west-2" region.
Dim bTls As Boolean = True
Dim port As Integer = 443
Dim bAutoReconnect As Boolean = True
Dim success As Boolean = rest.Connect("s3-us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials.
Dim authAws As New Chilkat.AuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"

' This particular bucket is in the Oregon region, as opposed to the US Standard,
' therefore the Region must be set appropriately.
' Also note that we connected to "s3-us-west-2.amazonaws.com".
authAws.Region = "us-west-2"

success = rest.SetAuthAws(authAws)

' Note: The above REST connection and setup of the AWS credentials
' can be done once.  After connecting, any number of REST calls can be made.
' The "auto reconnect" property passed to rest.Connect indicates that if
' the connection is lost, a REST method call will automatically reconnect
' if needed.
' --------------------------------------------------------------------------


' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkat.ocean".
' Note that the Host header should use "bucketName.s3.amazonaws.com", not "bucketName.s3-us-west-2.amazonaws.com"
rest.Host = "chilkat.ocean.s3.amazonaws.com"

' Our object is "starfish.jpg".
' Get the metadata.
' Since we are sending a HEAD request, we shouldn't use any of the Full* methods.
' Instead, send the request, then just read the response header.
success = rest.SendReqNoBody("HEAD","/starfish.jpg")
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' Now get the response header.
Dim statusCode As Integer = rest.ReadResponseHeader()
If (statusCode < 0) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' When successful, the S3 Storage service will respond with a 200 response code,
' with an XML body.  
If (statusCode <> 200) Then
    ' Examine the request/response to see what happened.
    Debug.WriteLine("response status code = " & statusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Exit Sub
End If


' The response header contains information about the S3 object.
' For example:

' 	HTTP/1.1 200 OK
' 	x-amz-id-2: GrV/hrB2EUkBlWc0h3JDdmVIrYDXfPC7CGvo/qSVRmYRPwilAOry8+4r2YWl4xJfa1HRYXrP808=
' 	x-amz-request-id: 4BDC6D6AEA0BDEF3
' 	Date: Mon, 13 May 2019 22:03:13 GMT
' 	Last-Modified: Mon, 10 Nov 2014 16:10:23 GMT
' 	ETag: "2e9c59dbf2662367dc97dfdda85da048"
' 	Accept-Ranges: bytes
' 	Content-Type: image/jpg
' 	Content-Length: 6229
' 	Server: AmazonS3

' Get the ETag response header value:
Dim etag As String = rest.ResponseHdrByName("ETag")
Debug.WriteLine("ETag: " & etag)