(VB.NET) S3 Complete a Multipart Upload

This operation completes a multipart upload by assembling previously uploaded parts.

Processing of a Complete Multipart Upload request could take several minutes to complete. After Amazon S3 begins processing the request, it sends an HTTP response header that specifies a 200 OK response. While processing is in progress, Amazon S3 periodically sends whitespace characters to keep the connection from timing out. Because a request could fail after the initial 200 OK response has been sent, it is important that you check the response body to determine whether the request succeeded.

This example sends a POST request to complete a multipart upload, which looks like this:

POST /ObjectName?uploadId=UploadId HTTP/1.1
Host: BucketName.s3.amazonaws.com
Date: Date
Content-Length: Size
Authorization: authorization string

<CompleteMultipartUpload>
  <Part>
    <PartNumber>PartNumber</PartNumber>
    <ETag>ETag</ETag>
  </Part>
  ...
</CompleteMultipartUpload>

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The 1st step in an S3 multipart upload is to initiate it,
' as shown here: Initiate S3 Multipart Upload

' The 2nd step is to upload the parts
' as shown here: S3 Upload Parts

' The 3rd and final step (this example) is to complete the multipart upload.

' Other S3 Multipart Upload Examples:
' Abort Multipart Upload
' List Parts


' When the multipart upload was initiated, an UploadId was provided in the XML response, and it 
' was saved to a file.  Steps 2 and 3 begin by loading the XML and getting
' the Upload ID.

Dim xmlInit As New Chilkat.Xml
Dim success As Boolean = xmlInit.LoadXmlFile("s3_multipart_uploads/initiate.xml")
If (success <> True) Then
    Debug.WriteLine("Did not find the initiate.xml XML file.")
    Exit Sub
End If


Dim uploadId As String = xmlInit.GetChildContent("UploadId")
Debug.WriteLine("UploadId = " & uploadId)

' We'll also need the XML file that contains a record of the parts
' with part numbers and ETags.  (This file was produced when parts were being uploaded.)
Dim xmlPartsList As New Chilkat.Xml
success = xmlPartsList.LoadXmlFile("s3_multipart_uploads/partsList.xml")
If (success <> True) Then
    Debug.WriteLine("Did not find the partsList.xml XML file.")
    Exit Sub
End If


Dim rest As New Chilkat.Rest

' Connect to the Amazon AWS REST server.
Dim bTls As Boolean = True
Dim port As Integer = 443
Dim bAutoReconnect As Boolean = True
success = rest.Connect("s3.amazonaws.com",port,bTls,bAutoReconnect)

' ----------------------------------------------------------------------------
' Important: For buckets created in regions outside us-east-1,
' there are three important changes that need to be made.
' See Working with S3 Buckets in Non-us-east-1 Regions for the details.
' ----------------------------------------------------------------------------

' Provide AWS credentials for the REST call.
Dim authAws As New Chilkat.AuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"

success = rest.SetAuthAws(authAws)

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkat100".
rest.Host = "chilkat100.s3.amazonaws.com"

' The "uploadId=UploadId" must be added as a query parameter.  This allows it to be 
' incorporated into the AWS signature calculation, which is a requirement.
' Therefore, we use AddQueryParam:
rest.AddQueryParam("uploadId",uploadId)

' Our ObjectName in this case is "somethingBig.zip".
Dim responseXml As String = rest.FullRequestString("POST","/somethingBig.zip",xmlPartsList.GetXml())
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' When successful, the S3 Storage service will respond with a 200 response code,
' with an XML body.  
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Debug.WriteLine("response body: " & responseXml)
    Debug.WriteLine("---")
    Debug.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    Debug.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
End If


' Load the XML response into Chilkat XMl and emit via GetXml to see the XML in a pretty-printed (indented) readable format.
Dim xml As New Chilkat.Xml
xml.LoadXml(responseXml)
Debug.WriteLine(xml.GetXml())
Debug.WriteLine("----")

Debug.WriteLine("Multipart upload completed.")