VB.NET

RSA Encrypt/Decrypt AES Key

See more RSA Examples

Demonstrates how to use RSA to protect a key for AES encryption. It can be used in this scenario: You will provide your RSA public key to any number of counterparts. Your counterpart will generate an AES key, encrypt data (or a file) using it, then encrypt the AES key using your RSA public key. Your counterpart sends you both the encrypted data and the encrypted key. Since you are the only one with access to the RSA private key, only you can decrypt the AES key. You decrypt the key, then decrypt the data using the AES key.

This example will show the entire process. (1) Generate an RSA key and save both private and public parts to PEM files. (2) Encrypt a file using a randomly generated AES encryption key. (3) RSA encrypt the AES key. (4) RSA decrypt the AES key. (5) Use it to AES decrypt the file or data.

VB.NET

Dim success As Boolean = False

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' ------------------
' Step 1.  Generate an RSA key and save to PEM files.

Dim rsa As New Chilkat.Rsa

' Generate a 2048-bit key. 
Dim privKey As New Chilkat.PrivateKey
success = rsa.GenKey(2048,privKey)
If (success = False) Then
    Debug.WriteLine(rsa.LastErrorText)
    Exit Sub
End If


Dim pubKey As New Chilkat.PublicKey
privKey.ToPublicKey(pubKey)

' For brevity, we are not checking the return value...
success = pubKey.SavePemFile(False,"qa_temp/pubKey.pem")
success = privKey.SavePemFile("qa_temp/privKey.pem")

' Other methods exist for saving the private key in PKCS8 format,
' both encrypted and un-encrypted..

' ------------------
' Step 2.   This is the code your counterpart will run to 
' AES encrypt a file.  It generates a random AES key
' to use for the encryption.

Dim crypt As New Chilkat.Crypt2

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 256

' Generate random bytes and return the random bytes
' in a hex string:
crypt.EncodingMode = "hex"
Dim randomKey As String = crypt.GenRandomBytesENC(32)
Debug.WriteLine("AES key = " & randomKey)

' Set the key.
crypt.SetEncodedKey(randomKey,"hex")

' Set the IV to a known value that will be used on both sides.
' (If desired, you could generate a random IV and protect it in the same
' way as the key...)
' The length of the IV for AES is always 16 bytes, regardless of the key size.
crypt.SetEncodedIV("000102030405060708090A0B0C0D0E0F","hex")

' AES Encrypt the file (the file may be any size because it will
' stream the file in/out.
success = crypt.CkEncryptFile("qa_data/hamlet.xml","qa_temp/aesEncrypted.dat")
If (success = False) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


' ------------------
' Step 3.
' ------------------
' RSA encrypt the AES key.
' We'll pretend  your counter part has the public-key PEM file and needs
' to load it.  Therefore, we'll start with a new RSA object and load
' the public key from the PEM..
Dim rsa2 As New Chilkat.Rsa

Dim pubKey2 As New Chilkat.PublicKey
success = pubKey2.LoadFromFile("qa_temp/pubKey.pem")
success = rsa2.UsePublicKey(pubKey2)

' RSA encrypt the AES key and return it as a base64 encoded string.
rsa2.EncodingMode = "base64"
Dim bUsePrivateKey As Boolean = False
Dim encryptedAesKey As String = rsa2.EncryptStringENC(randomKey,bUsePrivateKey)

' At this point, your counterpart sends you the encryptedAesKey,
' and the encrypted file.

' ------------------
' Step 4 - RSA decrypt the AES key.
' ------------------

' Start with a new RSA object and load the private key from the PEM.
Dim rsa3 As New Chilkat.Rsa
Dim privKey2 As New Chilkat.PrivateKey
success = privKey2.LoadPemFile("qa_temp/privKey.pem")
success = rsa3.UsePrivateKey(privKey2)

' The encrypted AES key is encoded using base64, so set
' our EncodingMode to "base64".
rsa3.EncodingMode = "base64"

bUsePrivateKey = True
Dim decryptedAesKey As String = rsa3.DecryptStringENC(encryptedAesKey,bUsePrivateKey)
Debug.WriteLine("decryptedAesKey = " & decryptedAesKey)

' ------------------
' Step 5 - AES decrypt the file.
' ------------------

Dim crypt2 As New Chilkat.Crypt2

crypt2.CryptAlgorithm = "aes"
crypt2.CipherMode = "cbc"
crypt2.KeyLength = 256

' Set the key.
crypt2.SetEncodedKey(decryptedAesKey,"hex")

' Set the IV 
crypt2.SetEncodedIV("000102030405060708090A0B0C0D0E0F","hex")

' AES Decrypt the file (the file may be any size because it will
' stream the file in/out.
success = crypt2.CkDecryptFile("qa_temp/aesEncrypted.dat","qa_temp/decrypted.xml")
If (success = False) Then
    Debug.WriteLine(crypt2.LastErrorText)
    Exit Sub
End If