VB.NET Requires Chilkat v11.0.0+

REST through SSH Tunnel

See more REST Examples

Demonstrates how to connect through an SSH Tunnel (via port-forwarding) to make REST API calls. VB.NET

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim tunnel As New Chilkat.Socket

Dim sshHostname As String = "sftp.example.com"
Dim sshPort As Integer = 22

'  Connect to an SSH server and establish the SSH tunnel:
success = tunnel.SshOpenTunnel(sshHostname,sshPort)
If (success = False) Then
    Debug.WriteLine(tunnel.LastErrorText)
    Exit Sub
End If


'  Authenticate with the SSH server via a login/password
'  or with a public key.
'  This example demonstrates SSH password authentication.
success = tunnel.SshAuthenticatePw("mySshLogin","mySshPassword")
If (success = False) Then
    Debug.WriteLine(tunnel.LastErrorText)
    Exit Sub
End If


'   OK, the SSH tunnel is setup.  Now open a channel within the tunnel.
'   (Any number of channels may be created from the same SSH tunnel.
'   Multiple channels may coexist at the same time.)

'  This example connects to a REST server through the SSH tunnel.
'  It will connect to the Amazon AWS service for this example.
Dim rest As New Chilkat.Rest

Dim bTls As Boolean = True
Dim port As Integer = 443
Dim maxWaitMs As Integer = 5000

'  This returns a socket object that is a single channel within the SSH tunnel.
Dim channel As New Chilkat.Socket
success = tunnel.SshNewChannel("s3.amazonaws.com",port,bTls,maxWaitMs,channel)
If (success = False) Then
    Debug.WriteLine(tunnel.LastErrorText)
    Exit Sub
End If


'  Use the connection.  (This connection is a TLS running on an SSH channel through an SSH tunnel.
'  In other words, TLS is wrapped within the SSH tunnel.)
success = rest.UseConnection(channel,True)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


'  Provide AWS credentials for the REST call.
Dim authAws As New Chilkat.AuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
success = rest.SetAuthAws(authAws)

'  List all buckets for the account...
Dim responseXml As String = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


Dim xml As New Chilkat.Xml
success = xml.LoadXml(responseXml)

'  Show the full XML returned.
Debug.WriteLine(xml.GetXml())

'  Iterate over the buckets, showing each bucket name.
success = xml.FindChild2("Buckets")
If (xml.FirstChild2() = True) Then
    Debug.WriteLine(xml.GetChildContent("Name"))
    While (xml.NextSibling2() = True)
        Debug.WriteLine(xml.GetChildContent("Name"))
    End While
End If

'  Move the internal pointer back to the root node.
xml.GetRoot2()