(VB.NET) Making SOAP Requests using the REST API

There's no reason a SOAP request cannot be sent using the REST API. It's only a matter of adding a SOAP specific header, and providing the SOAP XML request body. The response body is the SOAP response XML.

This example sends a request to ws.cdyne.com to get city weather by zip code.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' Demonstrates how to do a SOAP request using the REST API.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.


' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

Dim rest As New Chilkat.Rest

' This is the request to be sent:

' POST /WeatherWS/Weather.asmx HTTP/1.1
' Host: wsf.cdyne.com
' Content-Type: text/xml; charset=utf-8
' Content-Length: length
' SOAPAction: "http://ws.cdyne.com/WeatherWS/GetCityWeatherByZIP"
' 
' <?xml version="1.0" encoding="utf-8"?>
' <soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
'   <soap:Body>
'     <GetCityWeatherByZIP xmlns="http://ws.cdyne.com/WeatherWS/">
'       <ZIP>string</ZIP>
'     </GetCityWeatherByZIP>
'   </soap:Body>
' </soap:Envelope>

' Note: The application does not need to set the Host or Content-Length headers.
' Chilkat will automatically add these headers.


' Make the initial connection (without sending a request yet).
Dim bTls As Boolean = False
Dim port As Integer = 80
Dim bAutoReconnect As Boolean = True
' In this particular case, it is important to connect to "wsf.cdyne.com", not "ws.cdyne.com"...
Dim success As Boolean = rest.Connect("wsf.cdyne.com",port,bTls,bAutoReconnect)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' Add request headers:
success = rest.AddHeader("Content-Type","text/xml; charset=utf-8")
success = rest.AddHeader("SOAPAction","http://ws.cdyne.com/WeatherWS/GetCityWeatherByZIP")

' Build the SOAP XML request body.
Dim soapXml As New Chilkat.Xml

soapXml.Tag = "soap:Envelope"
success = soapXml.AddAttribute("xmlns:xsi","http://www.w3.org/2001/XMLSchema-instance")
success = soapXml.AddAttribute("xmlns:xsd","http://www.w3.org/2001/XMLSchema")
success = soapXml.AddAttribute("xmlns:soap","http://schemas.xmlsoap.org/soap/envelope/")

soapXml.NewChild2("soap:Body","")
success = soapXml.GetChild2(0)
soapXml.NewChild2("GetCityWeatherByZIP","")
success = soapXml.GetChild2(0)
success = soapXml.AddAttribute("xmlns","http://ws.cdyne.com/WeatherWS/")
soapXml.NewChild2("ZIP","60187")
soapXml.GetRoot2()

Debug.WriteLine(soapXml.GetXml())

' Send the SOAP request
Dim responseXml As String = rest.FullRequestString("POST","/WeatherWS/Weather.asmx",soapXml.GetXml())
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' When successful, the response status code will equal 200.
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Debug.WriteLine("response body (if any): " & responseXml)
    Debug.WriteLine("---")
    Debug.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    Debug.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    Exit Sub
End If


Dim xml As New Chilkat.Xml
success = xml.LoadXml(responseXml)

' GetXml will emit XML that is nicely indented for human viewing..
Debug.WriteLine(xml.GetXml())

' A sample response XML is shown below...

' To get some information, use ChilkatPath.  For example...
Debug.WriteLine("Temperature: " & xml.ChilkatPath("soap:Body|GetCityWeatherByZIPResponse|GetCityWeatherByZIPResult|Temperature|*"))

Debug.WriteLine("Success.")

' <?xml version="1.0" encoding="utf-8" ?>
' <soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
'     <soap:Body>
'         <GetCityWeatherByZIPResponse xmlns="http://ws.cdyne.com/WeatherWS/">
'             <GetCityWeatherByZIPResult>
'                 <Success>true</Success>
'                 <ResponseText>City Found</ResponseText>
'                 <State>IL</State>
'                 <City>Wheaton</City>
'                 <WeatherStationCity>West Chicago</WeatherStationCity>
'                 <WeatherID>10</WeatherID>
'                 <Description>Mostly Sunny</Description>
'                 <Temperature>33</Temperature>
'                 <RelativeHumidity>39</RelativeHumidity>
'                 <Wind>VRB5</Wind>
'                 <Pressure>30.33F</Pressure>
'                 <Visibility />
'                 <WindChill />
'                 <Remarks />
'             </GetCityWeatherByZIPResult>
'         </GetCityWeatherByZIPResponse>
'     </soap:Body>
' </soap:Envelope>