(VB.NET) REST OAuth1 with Params

Demonstrates how to use OAuth 1.0a "one legged" authentication with Woo Commerce, with URLs that use query parameters. For example: /orders?status=processing

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' Demonstrates how to do OAuth1 authentication with query parameters (for a Wordpress site using Woo Commerce).

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Prepare an OAuth 1.0 object for use with the Chilkat REST API.
Dim oauth1 As New Chilkat.OAuth1
oauth1.ConsumerKey = "WOO_COMMERCE_CONSUMER_KEY"
oauth1.ConsumerSecret = "WOO_COMMERCE_CONSUMER_SECRET"

' The signature method can be HMAC-SHA1 or HMAC-SHA256
oauth1.SignatureMethod = "HMAC-SHA256"

' The OauthUrl property will need to be updated each time a request is sent.
' The domain here must match the domain passed to the Connect method (below).
' The domain must be exact.  For example, "www.your-wordpress-site.com" vs. "your-wordpress-site.com".
' One might work while the other does not..
oauth1.OauthUrl = "http://your-wordpress-site.com/wc-api/v3/orders"

' We need to tell OAuth1 about our extra query parameters so they can be used
' in generating the OAuth1 signature.
' In this example, we want to add the param "status=processing"
Dim success As Boolean = oauth1.AddParam("status","processing")

' The OAuthMethod property will be set automatically when the REST request is sent.
' Setting it here is not actually necessary.
oauth1.OauthMethod = "GET"

' Generate an initial nonce so that Chilkat knows the desired size of the nonce.
success = oauth1.GenNonce(32)


Dim rest As New Chilkat.Rest

' Tell the REST object to use the OAuth1 object for authentication.
' Also, indicate that the OAuth authentication parameters should be query parameters
' and not located within the Authorization header.
Dim bUseQueryParams As Boolean = True
success = rest.SetAuthOAuth1(oauth1,bUseQueryParams)

' Make the initial connection (without sending a request yet) to the WooCommerce endpoint at your Wordpress blog.
Dim bTls As Boolean = False
Dim port As Integer = 80
Dim bAutoReconnect As Boolean = True
success = rest.Connect("your-wordpress-site.com",port,bTls,bAutoReconnect)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' Send a GET request to list orders.

' The extra query params must be added here.
' (Whatever params are added here should've also been added to the OAuth1 object.)
success = rest.AddQueryParam("status","processing")

' When the request is sent, the OAuth1 object's Timestamp and Nonce properties are automatically
' regenerated.  Also, the OAuth1 object's OauthMethod property is automatically set to the HTTP method
' used for the request (in this case it is "GET").
Dim responseJson As String = rest.FullRequestNoBody("GET","/wc-api/v3/orders")
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' When successful, the response status code will equal 200.
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Debug.WriteLine("response body (if any): " & responseJson)
    Debug.WriteLine("---")
    Debug.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    Debug.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    Exit Sub
End If


Debug.WriteLine(responseJson)
Debug.WriteLine("Success.")