(VB.NET) Lower-Level REST API Methods (Google Cloud Storage)

The FullRequest* methods, such as FullRequestBinary, FullRequestMultipart, FullRequestNoBody, FullRequestStream, FullRequestString, etc. are high-level REST API methods that both send the request and receive the response. It is often the case that an application needs make a REST call, but with a finer level of control. The Chilkat REST API provides this feature. An application can break a REST call into the following parts:

1. Send the HTTP request. (via the SendReq* methods)
2. Receive the HTTP response header. (ReadResponseHeader)
3. Receive the HTTP response body. (via the ReadRespBody* methods)

This example demonstrates a REST call using SendReqStringBody, ReadResonseHeader, and ReadRespBodyString.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example demonstrates a REST call using SendReqStringBody, ReadResonseHeader, and ReadRespBodyString.
' It will create a bucket in Google Cloud Storage.
Dim success As Boolean

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim gAuth As New Chilkat.AuthGoogle
' Obtain an access token as shown in one of the following examples:
' See Get Access Token using a Service Account JSON Key
' See Get Access Token using a P12 File


Dim rest As New Chilkat.Rest

' Connect using TLS.
Dim bAutoReconnect As Boolean = True
success = rest.Connect("www.googleapis.com",443,True,bAutoReconnect)

' Provide the authentication credentials (i.e. the access key)
success = rest.SetAuthGoogle(gAuth)

' Build the JSON request body for creating a bucket.
' The only required property is the "name", but we'll add more
' to make a better example..
Dim jsonReqBody As New Chilkat.JsonObject
success = jsonReqBody.AddStringAt(-1,"name","chilkat-bucket-c")
success = jsonReqBody.AddStringAt(-1,"kind","storage#bucket")
success = jsonReqBody.AddStringAt(-1,"location","US")
success = jsonReqBody.AddObjectAt(-1,"versioning")

Dim pObjVersioning As Chilkat.JsonObject = jsonReqBody.ObjectOf("versioning")
success = pObjVersioning.AddBoolAt(-1,"enabled",True)



' Show the HTTP request body we'll be sending.
Debug.WriteLine(jsonReqBody.Emit())

' Add the required query parameter.
' See https://cloud.google.com/storage/docs/json_api/v1/buckets/insert
success = rest.AddQueryParam("project","chilkattest-1050")

' Add the Content-Type HTTP request header.
success = rest.AddHeader("Content-Type","application/json; charset=UTF-8")

' Send the REST HTTP request.
success = rest.SendReqStringBody("POST","/storage/v1/b",jsonReqBody.Emit())
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' Read the response header.
Dim responseStatusCode As Integer = rest.ReadResponseHeader()
If (responseStatusCode < 0) Then
    ' We were unable to receive the response header.
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


If (responseStatusCode <> 200) Then
    ' The response was not successful.  We'll still need to receive 
    ' the response body, which may contain an error message from the server.
    ' If the response has no body, then the method for reading the
    ' response body can still be called.  It will simply return with an empty
    ' response body.

    ' We can examine the response header and status text:
    Debug.WriteLine("Response status text: " & rest.ResponseStatusText)
    Debug.WriteLine("Response header: " & rest.ResponseHeader)
End If


' Read the response body.  In this case we're expecting it to be JSON..
Dim responseBodyStr As String = rest.ReadRespBodyString()
If (rest.LastMethodSuccess <> True) Then
    ' We were unable to receive the response body.
    ' Note: If the response did not include a body (such as for cases where
    ' the Content-Length header is 0, or if the response status code implicitly
    ' indicates no body, then ReadRespBodyString returns cktrue, and the
    ' responseBodyString will be an empty string.
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' Show the JSON response.
Debug.WriteLine("Json Response: " & responseBodyStr)