(VB.NET) QuickBooks - Automatically Refresh Access Token with No User Interaction

Demonstrates how to automaticaly refresh an expired access token and retry the request after a 401 authorization error.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.


' Get our previously obtained OAuth2 access token, which should contain JSON like this:
' {
'   "expires_in": 3600,
'   "x_refresh_token_expires_in": 8726400,
'   "refresh_token": "L011546037639r ... 3vR2DrbOmg0Sdagw",
'   "access_token": "eyJlbmMiOiJBMTI4Q0 ... oETJEMbeggg",
'   "token_type": "bearer"
' }

Dim jsonToken As New Chilkat.JsonObject
Dim success As Boolean = jsonToken.LoadFile("qa_data/tokens/qb-access-token.json")

Dim rest As New Chilkat.Rest

' Connect using TLS.
' A single REST object, once connected, can be used for many Quickbooks REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim bAutoReconnect As Boolean = True
success = rest.Connect("sandbox-quickbooks.api.intuit.com",443,True,bAutoReconnect)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


Dim sbAuth As New Chilkat.StringBuilder
sbAuth.Append("Bearer ")
sbAuth.Append(jsonToken.StringOf("access_token"))
rest.Authorization = sbAuth.GetAsString()

rest.AddHeader("Accept","application/json")
rest.AllowHeaderFolding = False

' The company ID is 123146096291789
' The employee ID is 58
Dim responseBody As String = rest.FullRequestNoBody("GET","/v3/company/123146096291789/employee/58?minorversion=45")
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' If we get a 401 authorization error, then it's likely because the access token expired.
' We can automatically refresh it without interaction from the user.
If (rest.ResponseStatusCode = 401) Then

    Dim oauth2 As New Chilkat.OAuth2

    oauth2.TokenEndpoint = "https://oauth.platform.intuit.com/oauth2/v1/tokens/bearer"

    ' Replace these with actual values.
    oauth2.ClientId = "QUICKBOOKS-CLIENT-ID"
    oauth2.ClientSecret = "QUICKBOOKS-CLIENT-SECRET"

    ' Get the "refresh_token"
    oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

    ' Send the HTTP POST to refresh the access token..
    success = oauth2.RefreshAccessToken()
    If (success <> True) Then
        Debug.WriteLine(oauth2.LastErrorText)
        Exit Sub
    End If


    Debug.WriteLine("New access token: " & oauth2.AccessToken)

    ' Update the JSON with the new tokens.
    jsonToken.UpdateString("access_token",oauth2.AccessToken)

    ' Save the new JSON access token response to a file.
    ' The access + refresh tokens contained in this JSON will be needed for the next refresh.
    Dim sbJson As New Chilkat.StringBuilder
    jsonToken.EmitCompact = False
    jsonToken.EmitSb(sbJson)
    sbJson.WriteFile("qa_data/tokens/qb-access-token.json","utf-8",False)

    Debug.WriteLine("OAuth2 token refreshed!")
    Debug.WriteLine("New Access Token = " & oauth2.AccessToken)

    sbAuth.Clear()
    sbAuth.Append("Bearer ")
    sbAuth.Append(oauth2.AccessToken)
    rest.Authorization = sbAuth.GetAsString()

    ' Now retry the request with the refreshed access token...
    responseBody = rest.FullRequestNoBody("GET","/v3/company/123146096291789/employee/58?minorversion=45")
    If (rest.LastMethodSuccess <> True) Then
        Debug.WriteLine(rest.LastErrorText)
        Exit Sub
    End If

End If



' We should expect a 200 response if successful.
If (rest.ResponseStatusCode <> 200) Then
    Debug.WriteLine("Request Header: ")
    Debug.WriteLine(rest.LastRequestHeader)
    Debug.WriteLine("----")
    Debug.WriteLine("Response StatusCode = " & rest.ResponseStatusCode)
    Debug.WriteLine("Response StatusLine: " & rest.ResponseStatusText)
    Debug.WriteLine("Response Header:")
    Debug.WriteLine(rest.ResponseHeader)
    Debug.WriteLine(responseBody)
    Exit Sub
End If


' Load the JSON response into a JSON object for parsing.
' A sample JSON response is shown below.
Dim json As New Chilkat.JsonObject
json.Load(responseBody)

' These will be used for parsing date/time strings..
Dim dtime As New Chilkat.CkDateTime
Dim bLocalTime As Boolean = True
Dim dt As Chilkat.DtObj

' Show the JSON.   
json.EmitCompact = False
Debug.WriteLine(json.Emit())

' Get some information from the JSON..
Debug.WriteLine("Name: " & json.StringOf("Employee.DisplayName"))
Debug.WriteLine("Id: " & json.StringOf("Employee.Id"))
Debug.WriteLine("City: " & json.StringOf("Employee.PrimaryAddr.City"))
Debug.WriteLine("PostalCode: " & json.StringOf("Employee.PrimaryAddr.PostalCode"))

' Load the CreateTime into a CkDateTime...
dtime.SetFromTimestamp(json.StringOf("Employee.MetaData.CreateTime"))
dt = dtime.GetDtObj(bLocalTime)
Debug.WriteLine(dt.Month & "/" & dt.Day & "/" & dt.Year & "  " & dt.Hour & ":" & dt.Minute)


Debug.WriteLine("Success.")

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

' ------------------------------------------------------
' The JSON response looks like this:

' {
'   "Employee": {
'     "SSN": "XXX-XX-XXXX",
'     "PrimaryAddr": {
'       "Id": "116",
'       "Line1": "45 N. Elm Street",
'       "City": "Middlefield",
'       "CountrySubDivisionCode": "CA",
'       "PostalCode": "93242"
'     },
'     "BillableTime": false,
'     "domain": "QBO",
'     "sparse": false,
'     "Id": "98",
'     "SyncToken": "0",
'     "MetaData": {
'       "CreateTime": "2015-07-24T09:34:35-07:00",
'       "LastUpdatedTime": "2015-07-24T09:34:35-07:00"
'     },
'     "GivenName": "Bill",
'     "FamilyName": "Miller",
'     "DisplayName": "Bill Miller",
'     "PrintOnCheckName": "Bill Miller",
'     "Active": true,
'     "PrimaryPhone": {
'       "FreeFormNumber": "234-525-1234"
'     }
'   },
'   "time": "2015-07-24T09:35:54.805-07:00"
'