VB.NET

PKCS11 Import a Private Key onto the HSM

See more PKCS11 Examples

Demonstrates how to import an existing RSA private key onto the smartcard/token. The imported key is a token object, meaning it stays on the HSM and exists beyond the end of the PKCS11 session. VB.NET

Dim success As Boolean = False

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: Chilkat's PKCS11 implementation runs on Windows, Linux, Mac OS X, and other supported operating systems.

Dim pkcs11 As New Chilkat.Pkcs11

' Use the PKCS11 driver (.dll, .so, .dylib) for your particular HSM.
' (The format of the path will change with the operating system.  Obviously, "C:/" is not used on non-Windows systems.
pkcs11.SharedLibPath = "C:/Program Files (x86)/Gemalto/IDGo 800 PKCS#11/IDPrimePKCS1164.dll"

' Establish a logged-on session.
Dim pin As String = "0000"
Dim userType As Integer = 1
success = pkcs11.QuickSession(userType,pin)
If (success = False) Then
    Debug.WriteLine(pkcs11.LastErrorText)
    Exit Sub
End If


' Let's import a certificate's private key onto the HSM.
' First, we'll load the certificate from a .pfx (also known as .p12), which is a file format
' that also includes the certificate's private key.
Dim cert As New Chilkat.Cert
success = cert.LoadPfxFile("qa_data/pfx/ehealth.fgov.be_testing.p12","p12_password")
If (success = False) Then
    Debug.WriteLine(cert.LastErrorText)
    Exit Sub
End If


' Let's get the certificate's private key.
Dim privKey As New Chilkat.PrivateKey
success = cert.GetPrivateKey(privKey)
If (success = False) Then
    Debug.WriteLine(cert.LastErrorText)
    Exit Sub
End If


' Build a PKCS11 template to provide additional information about the key to be imported.
Dim jsonTemplate As New Chilkat.JsonObject

' Indicate that the key is to be stored on the token.  It is NOT a session object.
jsonTemplate.UpdateBool("token",True)

' Indicate that the key can be used for signing.
jsonTemplate.UpdateBool("sign",True)

' Provide an arbitrary ID and label (anything you want).
' The information in the ID and/or label provides one means for finding the key in future PKCS11 sessions.
jsonTemplate.UpdateString("id_hex","010203040A0B0C0D0E0F")
jsonTemplate.UpdateString("label","ehealth private key")

' Import the key.  The private key handle is returned on success.  Otherwise 0 is returned.
' If our only task for now is to simply import the key, we can ignore the returned handle, 
' other than to check for success/failure.  Otherwise, the handle can be used in other PKCS11 operations.
' This example just creates the key and does not use the returned handle.
Dim keyHandle As UInt32 = pkcs11.ImportPrivateKey(privKey,jsonTemplate)
If (keyHandle = 0) Then
    Debug.WriteLine(pkcs11.LastErrorText)
Else
    Debug.WriteLine("key handle = " & keyHandle)
    Debug.WriteLine("Successfully imported a private key onto the HSM.")
End If


pkcs11.Logout()
pkcs11.CloseSession()