(VB.NET) PKCS11 Generate an EC Key that stays on the HSM

See more PKCS11 Examples

Generates an EC key on the smart card or token and returns the public and private key handles. The generated EC key stays on the HSM even after the PKCS11 session has ended.

Note: This example requires Chilkat v9.5.0.96 or later.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: Chilkat's PKCS11 implementation runs on Windows, Linux, Mac OS X, and other supported operating systems.

Dim pkcs11 As New Chilkat.Pkcs11

' Use the PKCS11 driver (.dll, .so, .dylib) for your particular HSM.
' (The format of the path will change with the operating system.  Obviously, "C:/" is not used on non-Windows systems.
pkcs11.SharedLibPath = "C:/Program Files (x86)/Gemalto/IDGo 800 PKCS#11/IDPrimePKCS1164.dll"

' Establish a logged-on session.
Dim pin As String = "0000"
Dim userType As Integer = 1
Dim success As Boolean = pkcs11.QuickSession(userType,pin)
If (success = False) Then
    Debug.WriteLine(pkcs11.LastErrorText)
    Exit Sub
End If


' ------------------------------------------------------------------------------
' Specify attributes and abilities (how this key can be used) by providing a JSON template.
' One template is for the public key, and the other for the private key.
Dim pubKeyAttr As New Chilkat.JsonObject

' Generate an EC key that remains on the HSM by setting the "token" attribute equal to True
pubKeyAttr.UpdateBool("token",True)

' Given that our key will reside on the token, we should give it two attributes (id and label) to help us
' find it in future sessions.

' First, we can give it an arbitrary ID.  ID's are binary, so we specify bytes as either 
' "id_hex" for hexidecimal bytes, 
' "id_ascii" for the bytes of an ascii string, 
' "id" for bytes in base64 format.
Dim keyId As String = "0102030405060708090A"
pubKeyAttr.UpdateString("id_hex",keyId)

' We can also give our key a label with any descriptive string.
Dim keyLabel As String = "secp256r1 EC key for testing"
pubKeyAttr.UpdateString("label",keyLabel)

' -----------------------------------------------------------------------------------
' IMPORTANT: The ID for the public key must be the same as the ID for the private key.
' -----------------------------------------------------------------------------------

' Allow the public key to be used for signature verification
pubKeyAttr.UpdateBool("verify",True)

' Specify the kind of EC key to generate by the curve name
' Possible curve names are:
' secp256r1  (also known as P-256 and prime256v1)
' secp384r1  (also known as P-384)
' secp521r1  (also known as P-521)
' secp256k1 (This is the curve used for Bitcoin)
' secp192r1
' secp224r1
' brainpoolP160r1
' brainpoolP192r1
' brainpoolP192r1
' brainpoolP224r1
' brainpoolP256r1
' brainpoolP320r1
' brainpoolP384r1
' brainpoolP512r1
' Note: Your smart card or token might not support all of the above EC curves (assuming it supports EC at all).

' This attribute is required.
pubKeyAttr.UpdateString("ec_params","secp256r1")

' ------------------------------------------------------------------------------
Dim privKeyAttr As New Chilkat.JsonObject

' Generate an EC key that remains on the HSM by setting the "token" attribute equal to True
privKeyAttr.UpdateBool("token",True)

' Make sure we give the private key the same ID as the public key.
privKeyAttr.UpdateString("id_hex",keyId)

' We can also give our key a label with any descriptive string.
' (Best to use the same label as for the public key)
privKeyAttr.UpdateString("label",keyLabel)

' Allow the private key to be used for signing.
privKeyAttr.UpdateBool("sign",True)

' Provide a JSON object to receive the public and private key handles.
Dim jsonHandles As New Chilkat.JsonObject
jsonHandles.EmitCompact = False

' Provide a Chilkat public key object to receive the public key.
Dim pubKey As New Chilkat.PublicKey

success = pkcs11.GenEcKey(pubKeyAttr,privKeyAttr,jsonHandles,pubKey)
If (success = False) Then
    Debug.WriteLine(pkcs11.LastErrorText)
    Debug.WriteLine("Failed to generate an EC key.")
Else
    ' Sample JSON handles:
    ' {
    '   "public_key_handle": 18415630,
    '   "private_key_handle": 74842125
    ' }
    Debug.WriteLine(jsonHandles.Emit())
    Debug.WriteLine("public_key_handle: " & jsonHandles.UIntOf("public_key_handle"))
    Debug.WriteLine("private_key_handle: " & jsonHandles.UIntOf("private_key_handle"))
    Debug.WriteLine("public key JWK:")
    Debug.WriteLine(pubKey.GetJwk())
    ' Sample JWK:
    ' {"kty":"EC","crv":"P-256","x":"EDy-Sxl0DZ8tvzy_qnIYl6DYPFjTVnyJ2I9ZTCfKds4","y":"yBZ4HK2yF7F7ZEOn59CgTQp2ApQJ8ZOF736yZxY6LOE"}
    Debug.WriteLine("Success.")
End If


pkcs11.Logout()
pkcs11.CloseSession()