(VB.NET) OneDrive -- Upload Large Files with an Upload Session

See more OneDrive Examples

Demonstrates how to upload large files with an upload session. See OneDrive Upload Session for more general information.

Note: This example requires Chilkat v9.5.0.97 or greater.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Boolean

' This example uses the OAuth client credentials flow.
' See How to Create an Azure App Registration for OAuth 2.0 Client Credentials

' Use your client ID, client secret, and tenant ID in the following lines
Dim json As New Chilkat.JsonObject
json.UpdateString("client_id","2871da2c-8176-4b7f-869b-2311aa82e743")
json.UpdateString("client_secret","2hu9Q~r5QuryUcEkNbg1btLtnfU1VUXzhSCG6brH")
json.UpdateString("scope","https://graph.microsoft.com/.default")
json.UpdateString("token_endpoint","https://login.microsoftonline.com/114d7ed6-71bf-4dbe-a866-748364121bf2/oauth2/v2.0/token")

Dim http As New Chilkat.Http
http.AuthToken = json.Emit()

' ----------------------------------------------------------------------------
' Step 1: Create an upload session

' To begin a large file upload, your app must first request a new upload session. This creates a 
' temporary storage location where the bytes of the file will be saved until the complete file is uploaded. 
' Once the last byte of the file has been uploaded the upload session is completed and the final file is shown 
' in the destination folder.

' Send the following POST to create an upload session:
' If not using "me", then the path should be /v1.0/users/{id | userPrincipalName}/...
' POST /v1.0/users/{user_id}/drive/root:/{path_to_item}:/createUploadSession

http.SetUrlVar("path_to_item","/somefolder/big.zip")
http.SetUrlVar("user_id","4fe732c3-322e-4a6b-b729-2fd1eb5c6104")
Dim url As String = "https://graph.microsoft.com/v1.0/users/{$user_id}/drive/root:/{$path_to_item}:/createUploadSession"
Dim resp As Chilkat.HttpResponse = http.PostJson2(url,"application/json","{}")
If (http.LastMethodSuccess <> True) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


' If successful, a 200 status code is returned, with the session details (in JSON format).
Dim jsonSession As New Chilkat.JsonObject
jsonSession.EmitCompact = False
jsonSession.Load(resp.BodyStr)

If (resp.StatusCode <> 200) Then

    Debug.WriteLine(jsonSession.Emit())
    Debug.WriteLine("Response status = " & resp.StatusCode)

    Exit Sub
End If




Debug.WriteLine(jsonSession.Emit())

' A sample response:

' 	{
' 	  "@odata.context": "https://graph.microsoft.com/v1.0/$metadata#microsoft.graph.uploadSession",
' 	  "uploadUrl": "https://api.onedrive.com/rup/3a33fceb9b74cc15/eyJSZXNvdXJjZUlEI ... 65yDYUiS3JTDnnhqCHxw",
' 	  "expirationDateTime": "2017-06-11T12:40:23.239Z",
' 	  "nextExpectedRanges": [
' 	    "0-"
' 	  ]
' 	}
' 

' ----------------------------------------------------------------------------
' Step 2: Upload Data in Segments (a.k.a. Fragments or Chunks)

' Microsoft states this requirement: Use a fragment size that is a multiple of 320 KiB (320 * 1024 bytes). 
' Failing to use a fragment size that is a multiple of 320 KiB can result in large file transfers failing after the 
' last fragment is uploaded.  (Note: This is a detail imposed by Microsoft's OneDrive server-side implementation.)

Dim fragSize As Integer = 320 * 1024
Dim localFilePath As String = "qa_data/zips/big.zip"

' Upload the file big.zip in 320KiB segments.
' Note: The FileSize method returns a signed 32-bit integer.  If the file is potentially larger than 2GB, call FileSizeStr instead to return
' the size of the file as a string, then convert to an integer value.
Dim fac As New Chilkat.FileAccess
Dim fileSize As Integer = fac.FileSize(localFilePath)

' Open the file to get the number of fragments.
success = fac.OpenForRead(localFilePath)
If (success = False) Then
    Debug.WriteLine(fac.LastErrorText)
    Exit Sub
End If

Dim numFragments As Integer = fac.GetNumBlocks(fragSize)
fac.FileClose()

Dim i As Integer = 0

Debug.WriteLine("fileSize = " & fileSize)
Debug.WriteLine("numFragments = " & numFragments)

Dim uploadUrl As New Chilkat.Url
uploadUrl.ParseUrl(jsonSession.StringOf("uploadUrl"))

json.EmitCompact = False

Dim req As New Chilkat.HttpRequest
req.HttpVerb = "PUT"
req.Path = uploadUrl.PathWithQueryParams
req.ContentType = "application/octet-stream"

Dim sbOffset As New Chilkat.StringBuilder
Dim sbNumBytes As New Chilkat.StringBuilder
Dim sbRange As New Chilkat.StringBuilder

' IMPORTANT: The uploadUrl is a temporary URL to be used to upload the fragment.
' It requires no authentication (because the URL itself could only have been obtained from an authenticated
' request to start the upload session).  Therefore, do not allow the upload URL to be publicly seen,
' otherwise anybody could upload to your OneDrive.
http.AuthToken = ""

Dim bytesRemaining As Integer = fileSize
While i < numFragments

    ' The success response code for intermediate chunks is 202,
    ' whereas the final chunk will have a 201 success response where
    ' the response body is the JSON DriveItem.
    Dim chunkSize As Integer = fragSize
    Dim expectedStatusCode As Integer = 202
    If (bytesRemaining < chunkSize) Then
        chunkSize = bytesRemaining
        expectedStatusCode = 201
    End If

    Debug.WriteLine("  this chunkSize = " & chunkSize)

    ' Indicate the fragment in the local file to be streamed in the upload.
    sbOffset.Clear()
    sbOffset.AppendInt(i * fragSize)
    sbNumBytes.Clear()
    sbNumBytes.AppendInt(chunkSize)
    req.StreamChunkFromFile(localFilePath,sbOffset.GetAsString(),sbNumBytes.GetAsString())

    ' The Content-Range header field must be set for this fragment.  For example:
    ' Content-Range: bytes 0-25/128
    sbRange.SetString("bytes start-end/fileSize")
    Dim numReplaced As Integer = sbRange.ReplaceI("start",i * fragSize)
    numReplaced = sbRange.ReplaceI("end",i * fragSize + chunkSize - 1)
    numReplaced = sbRange.ReplaceI("fileSize",fileSize)
    req.AddHeader("Content-Range",sbRange.GetAsString())
    Debug.WriteLine("  this content-range: " & sbRange.GetAsString())

    resp = http.SynchronousRequest(uploadUrl.Host,443,True,req)
    If (http.LastMethodSuccess <> True) Then
        Debug.WriteLine(http.LastErrorText)
        Exit Sub
    End If


    json.Load(resp.BodyStr)
    ' A 202 response status code indicates success.
    If (resp.StatusCode <> expectedStatusCode) Then

        Debug.WriteLine(json.Emit())
        Debug.WriteLine("Response status = " & resp.StatusCode)

        Exit Sub
    End If


    Debug.WriteLine(json.Emit())
    Debug.WriteLine("---- Chunk " & i & " uploaded ----")

    bytesRemaining = bytesRemaining - chunkSize
    i = i + 1
End While

Debug.WriteLine("data uploaded.")

' ----------------------------------------------------------------------------
' Sample output for the above session:

' {
'   "@odata.context": "https://graph.microsoft.com/v1.0/$metadata#microsoft.graph.uploadSession",
'   "uploadUrl": "https://api.onedrive.com/rup/3a33fceb9b74cc15/eyJSZXNvd ... QoKK2iuh1A",
'   "expirationDateTime": "2017-06-11T14:04:45.438Z",
'   "nextExpectedRanges": [
'     "0-"
'   ]
' }
' 
' fileSize = 1366807
' numFragments = 5
'   this chunkSize = 327680
'   this content-range: bytes 0-327679/1366807
' {
'   "expirationDateTime": "2017-06-11T14:04:45.438Z",
'   "nextExpectedRanges": [
'     "327680-1366806"
'   ]
' }
' 
' ---- Chunk 0 uploaded ----
'   this chunkSize = 327680
'   this content-range: bytes 327680-655359/1366807
' {
'   "expirationDateTime": "2017-06-11T14:04:45.438Z",
'   "nextExpectedRanges": [
'     "655360-1366806"
'   ]
' }
' 
' ---- Chunk 1 uploaded ----
'   this chunkSize = 327680
'   this content-range: bytes 655360-983039/1366807
' {
'   "expirationDateTime": "2017-06-11T14:04:45.438Z",
'   "nextExpectedRanges": [
'     "983040-1366806"
'   ]
' }
' 
' ---- Chunk 2 uploaded ----
'   this chunkSize = 327680
'   this content-range: bytes 983040-1310719/1366807
' {
'   "expirationDateTime": "2017-06-11T14:04:45.438Z",
'   "nextExpectedRanges": [
'     "1310720-1366806"
'   ]
' }
' 
' ---- Chunk 3 uploaded ----
'   this chunkSize = 56087
'   this content-range: bytes 1310720-1366806/1366807
' {
'   "createdBy": {
'     "application": {
'       "displayName": "Chilkat",
'       "id": "441c9990"
'     },
'     "user": {
'       "id": "3a33fceb9b74cc15"
'     }
'   },
'   "createdDateTime": "2017-06-04T14:04:47.247Z",
'   "cTag": "aYzozQTMzRkNFQjlCNzRDQzE1ITQ4NjguMjU3",
'   "eTag": "aM0EzM0ZDRUI5Qjc0Q0MxNSE0ODY4LjA",
'   "id": "3A33FCEB9B74CC15!4868",
'   "lastModifiedBy": {
'     "application": {
'       "displayName": "Chilkat",
'       "id": "441c9990"
'     },
'     "user": {
'       "id": "3a33fceb9b74cc15"
'     }
'   },
'   "lastModifiedDateTime": "2017-06-04T14:04:47.247Z",
'   "name": "big.zip",
'   "parentReference": {
'     "driveId": "3a33fceb9b74cc15",
'     "id": "3A33FCEB9B74CC15!4862",
'     "name": "someFolder",
'     "path": "/drive/root:/someFolder"
'   },
'   "size": 1366807,
'   "webUrl": "https://1drv.ms/u/s!ABXMdJvr_DM6pgQ",
'   "file": {
'     "hashes": {
'       "sha1Hash": "252059AA13004220DB912B97D4D3FF9599CCD8D9"
'     },
'     "mimeType": "application/zip"
'   },
'   "fileSystemInfo": {
'     "createdDateTime": "2017-06-04T14:04:47.246Z",
'     "lastModifiedDateTime": "2017-06-04T14:04:47.246Z"
'   },
'   "tags": [
'   ],
'   "lenses": [
'   ]
' }
' 
' Response status = 201