VB.NET

OAuth2 using an HTTP Proxy (for a Desktop Application)

See more OAuth2 Examples

Shows how to send OAuth2 communications through an HTTP proxy in a desktop application, using Microsoft Graph as an example. This method applies to all OAuth2 applications. VB.NET

Dim success As Boolean = False

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' To use an HTTP proxy with OAuth2, create a Chilkat socket object and specify the details.
Dim socket As New Chilkat.Socket
' Use your HTTP proxy server domain or IP address.
socket.HttpProxyHostname = "myproxyserver.com"
' Change this to the listening port of your HTTP proxy server (if necessary)
socket.HttpProxyPort = 808
' Specify login/password if needed.
socket.HttpProxyUsername = "myProxyLogin"
socket.HttpProxyPassword = "myProxyPassword"
socket.HttpProxyForHttp = True

Dim oauth2 As New Chilkat.OAuth2

' We don't need to connect the socket beforehand.
' Just tell oauth2 to use the socket which has the HTTP proxy properties.
success = oauth2.UseConnection(socket)

' This should be the port in the localhost callback URL for your app.  
' The callback URL would look like "http://localhost:3017/" if the port number is 3017.
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://login.microsoftonline.com/common/oauth2/v2.0/authorize"
oauth2.TokenEndpoint = "https://login.microsoftonline.com/common/oauth2/v2.0/token"

' Replace these with actual values.
oauth2.ClientId = "MICROSOFT-GRAPH-CLIENT-ID"
' This is your app password:
oauth2.ClientSecret = "MICROSOFT-GRAPH-CLIENT-SECRET"

oauth2.CodeChallenge = False
' Provide a SPACE separated list of scopes.
' See https://developer.microsoft.com/en-us/graph/docs/authorization/permission_scopes 

' Important: To get a refresh token in the final response, you have to ask for "offline_access" scope
oauth2.Scope = "openid profile offline_access user.readwrite mail.readwrite mail.send files.readwrite"

' Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
Dim url As String = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> True) Then
    Debug.WriteLine(oauth2.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("url = " & url)

' Launch the default browser on the system and navigate to the url.
' The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = False) Then
    Debug.WriteLine(oauth2.LastErrorText)
    Exit Sub
End If


' Wait for the user to approve or deny authorization in the browser.
Dim numMsWaited As Integer = 0
While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs(100)
    numMsWaited = numMsWaited + 100
End While

' If the browser does not respond within the specified time, AuthFlowState will be:
' 
' 1: Waiting for Redirect - The OAuth2 background thread is waiting for the browser's redirect request.
' 2: Waiting for Final Response - The thread is awaiting the final access token response.
' In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    oauth2.Cancel()
    Debug.WriteLine("No response from the browser!")
    Exit Sub
End If


' Check AuthFlowState to determine if authorization was granted, denied, or failed:
' 
' 3: Success - OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
' 4: Access Denied - OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
' 5: Failure - OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    Debug.WriteLine("OAuth2 failed to complete.")
    Debug.WriteLine(oauth2.FailureInfo)
    Exit Sub
End If


If (oauth2.AuthFlowState = 4) Then
    Debug.WriteLine("OAuth2 authorization was denied.")
    Debug.WriteLine(oauth2.AccessTokenResponse)
    Exit Sub
End If


If (oauth2.AuthFlowState <> 3) Then
    Debug.WriteLine("Unexpected AuthFlowState:" & oauth2.AuthFlowState)
    Exit Sub
End If


Debug.WriteLine("OAuth2 authorization granted!")
Debug.WriteLine("Access Token = " & oauth2.AccessToken)

' Get the full JSON response:
Dim json As New Chilkat.JsonObject
json.Load(oauth2.AccessTokenResponse)
json.EmitCompact = False

' The JSON response looks like this:

' {
'   "token_type": "Bearer",
'   "scope": "User.Read Mail.ReadWrite Mail.Send",
'   "expires_in": 3600,
'   "ext_expires_in": 0,
'   "access_token": "EwBAA8l6B...",
'   "refresh_token": "MCRMdbe...",
'   "id_token": "eyJ0eXA..."
' }

' If an "expires_on" member does not exist, then add the JSON member by
' getting the current system date/time and adding the "expires_in" seconds.
' This way we'll know when the token expires.
If (json.HasMember("expires_on") <> True) Then
    Dim dtExpire As New Chilkat.CkDateTime
    dtExpire.SetFromCurrentSystemTime()
    dtExpire.AddSeconds(json.IntOf("expires_in"))
    json.AppendString("expires_on",dtExpire.GetAsUnixTimeStr(False))
End If


Debug.WriteLine(json.Emit())

' Save the JSON to a file for future requests.
Dim fac As New Chilkat.FileAccess
fac.WriteEntireTextFile("qa_data/tokens/microsoftGraph.json",json.Emit(),"utf-8",False)