(VB.NET) NTLM Client and Server Code

Demonstrates the NTLM authentication algorithm for both client and server.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ntlmClient As New Chilkat.Ntlm
Dim ntlmServer As New Chilkat.Ntlm

' The NTLM protocol begins by the client sending the server
' a Type1 message. 
Dim type1Msg As String
ntlmClient.Workstation = "MyWorkstation"
type1Msg = ntlmClient.GenType1()

Debug.WriteLine("Type1 message from client to server:")
Debug.WriteLine(type1Msg)

' If the server wishes to examine the information embedded within the
' Type1 message, it may call ParseType1. 
' This step is not necessary, it is only for informational purposes..
Dim type1Info As String = ntlmServer.ParseType1(type1Msg)

Debug.WriteLine("---")
Debug.WriteLine(type1Info)

' The server now generates a Type2 message to be sent to the client.
' The Type2 message requires a TargetName.  A TargetName is
' the authentication realm in which the authenticating account
' has membership (a domain name for domain accounts, or server name
' for local machine accounts).
ntlmServer.TargetName = "myAuthRealm"

Dim type2Msg As String = ntlmServer.GenType2(type1Msg)
If (ntlmServer.LastMethodSuccess <> True) Then
    Debug.WriteLine(ntlmServer.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("Type2 message from server to client:")
Debug.WriteLine(type2Msg)

' The client may examine the information embedded in the Type2 message 
' by calling ParseType2, which returns XML.  This is only for informational purposes
' and is not required.
Dim type2Info As String = ntlmClient.ParseType2(type2Msg)

Debug.WriteLine("---")
Debug.WriteLine(type2Info)

' The client will now generate the final Type3 message to be sent to the server.
' This requires the Username and Password:
ntlmClient.UserName = "test123"
ntlmClient.Password = "myPassword"

Dim type3Msg As String
type3Msg = ntlmClient.GenType3(type2Msg)
If (ntlmClient.LastMethodSuccess <> True) Then
    Debug.WriteLine(ntlmClient.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("Type3 message from client to server:")
Debug.WriteLine(type3Msg)

' The server may verify the response by first "loading" the Type3 message.
' This sets the various properties such as Username, Domain, Workstation,
' and ClientChallenge to the values embedded within theType3 message.
' The server may then use the Username to lookup the password.  
' Looking up the password is dependent on your infrastructure.  Perhaps your
' usernames/passwords are stored in a secure database.  If that's the case, you would
' write code to issue a query to get the password string for the given username.
' Once the password is obtained, set the Password property and then 
' generate the Type3 response again.  If the server's Type3 response matches
' the client's Type3 response, then the client's password is correct.

Dim success As Boolean = ntlmServer.LoadType3(type3Msg)
If (success <> True) Then
    Debug.WriteLine(ntlmServer.LastErrorText)
    Exit Sub
End If


' The Username property now contains the username that was embedded within
' the Type3 message.  It can be used to lookup the password.
Dim clientUsername As String = ntlmServer.UserName

' For this example, we'll simply set the password to a literal string:
ntlmServer.Password = "myPassword"

' The server may generate the Type3 message again, using the client's correct
' password:
Dim expectedType3Msg As String = ntlmServer.GenType3(type2Msg)

Debug.WriteLine("Expected Type3 Message:")
Debug.WriteLine(expectedType3Msg)

' If the Type3 message received from the client is exactly the same as the
' expected Type3 message, then the client must've used the same password,
' and authentication is successful