(VB.NET) Validate a JWS Using ECDSA P-256 SHA-256

Validates a JSON Web Signature (JWS) that uses ECDSA P-256 SHA-256

Note: This example requires Chilkat v9.5.0.66 or greater.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.

' This example takes a JSON signature in compact serialization format,
' and uses an ECDSA public key to validate and recover the protected header and payload.

' We only need a public key for signature validation.  This is the ECDSA public key
' that is used:

'      {"kty":"EC", 
'       "crv":"P-256", 
'       "x":"f83OJ3D2xF1Bg8vub9tLe1gHMzV76e8Tus9uPHvRVEU", 
'       "y":"x_FEzRu9m36HLN_tue659LNpXW6pCyStikYjKIWI5a0" 
'      } 

Dim sbPubKey As New Chilkat.StringBuilder
sbPubKey.Append("{""kty"":""EC"",")
sbPubKey.Append("""crv"":""P-256"",")
sbPubKey.Append("""x"":""f83OJ3D2xF1Bg8vub9tLe1gHMzV76e8Tus9uPHvRVEU"",")
sbPubKey.Append("""y"":""x_FEzRu9m36HLN_tue659LNpXW6pCyStikYjKIWI5a0""")
sbPubKey.Append("}")

Dim pubKey As New Chilkat.PublicKey
Dim success As Boolean = pubKey.LoadFromString(sbPubKey.GetAsString())
If (success <> True) Then
    Debug.WriteLine(pubKey.LastErrorText)
    Exit Sub
End If


Dim jws As New Chilkat.Jws

' Set the ECC public key:
Dim signatureIndex As Integer = 0
jws.SetPublicKey(signatureIndex,pubKey)

' Load the JWS.
Dim sbJws As New Chilkat.StringBuilder
sbJws.Append("eyJhbGciOiJFUzI1NiJ9")
sbJws.Append(".")
sbJws.Append("eyJpc3MiOiJqb2UiLA0KICJleHAiOjEzMDA4MTkzODAsDQogImh0dHA6Ly9leGFt")
sbJws.Append("cGxlLmNvbS9pc19yb290Ijp0cnVlfQ")
sbJws.Append(".")
sbJws.Append("DtEhU3ljbEg8L38VWAfUAqOyKAM6-Xx-F4GawxaepmXFCgfTjDxw5djxLa8ISlSA")
sbJws.Append("pmWQxfKTUJqPP3-Kg6NU1Q")

success = jws.LoadJwsSb(sbJws)
If (success <> True) Then
    Debug.WriteLine(jws.LastErrorText)
    Exit Sub
End If


' Validate the 1st (and only) signature at index 0..
Dim v As Integer = jws.Validate(signatureIndex)
If (v < 0) Then
    ' Perhaps Chilkat was not unlocked or the trial expired..
    Debug.WriteLine("Method call failed for some other reason.")
    Debug.WriteLine(jws.LastErrorText)
    Exit Sub
End If

If (v = 0) Then
    Debug.WriteLine("Invalid signature.  The ECC key was incorrect, the JWS was invalid, or both.")
    Exit Sub
End If


' If we get here, the signature was validated..
Debug.WriteLine("Signature validated.")
Debug.WriteLine("--")

' Recover the original content:
Debug.WriteLine("Recovered content:")
Debug.WriteLine(jws.GetPayload("utf-8"))
Debug.WriteLine("--")

' Examine the protected header:
Dim joseHeader As Chilkat.JsonObject = jws.GetProtectedHeader(signatureIndex)
If (jws.LastMethodSuccess <> True) Then
    Debug.WriteLine("No protected header found at the given index.")
    Exit Sub
End If

joseHeader.EmitCompact = False

Debug.WriteLine("Protected (JOSE) header:")
Debug.WriteLine(joseHeader.Emit())


' Output:

' 	Signature validated.
' 	--
' 	Recovered content:
' 	{"iss":"joe",
' 	 "exp":1300819380,
' 	 "http://example.com/is_root":true}
' 	--
' 	Protected (JOSE) header:
' 	{ 
' 	  "alg": "ES256"
' 	}