(VB.NET) Create a JWS Using ECDSA P-521 SHA-512

Creates and verifies a JSON Web Signature (JWS) that uses ECDSA P-521 SHA-512

Note: This example requires Chilkat v9.5.0.66 or greater.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.

' Use the following ECC key loaded from JWK format.
Dim sbJwk As New Chilkat.StringBuilder
sbJwk.Append("{""kty"":""EC"",")
sbJwk.Append("""crv"":""P-521"",")
sbJwk.Append("""x"":""AekpBQ8ST8a8VcfVOTNl353vSrDCLLJXmPk06wTjxrrjcBpXp5EOnYG_NjFZ6OvLFV1jSfS9tsz4qUxcWceqwQGk"",")
sbJwk.Append("""y"":""ADSmRA43Z1DSNx_RvcLI87cdL07l6jQyyBXMoxVg_l2Th-x3S1WDhjDly79ajL4Kkd0AZMaZmh9ubmf63e3kyMj2"",")
sbJwk.Append("""d"":""AY5pb7A0UFiB3RELSD64fTLOSV_jazdF7fLYyuTw8lOfRhWg6Y6rUrPAxerEzgdRhajnu0ferB0d53vM9mE15j2C""")
sbJwk.Append("}")

Dim eccKey As New Chilkat.PrivateKey
' Note: This example loads the ECDSA key from JWK format.  Any format can be loaded
' into the private key object. (See the online reference documentation..)
Dim success As Boolean = eccKey.LoadJwk(sbJwk.GetAsString())
If (success <> True) Then
    Debug.WriteLine(eccKey.LastErrorText)
    Exit Sub
End If


' Create the JWS Protected Header
Dim jwsProtHdr As New Chilkat.JsonObject
jwsProtHdr.AppendString("alg","ES512")

Dim jws As New Chilkat.Jws

' Set the protected header:
Dim signatureIndex As Integer = 0
jws.SetProtectedHeader(signatureIndex,jwsProtHdr)

' Set the ECC key:
jws.SetPrivateKey(signatureIndex,eccKey)

' Set the payload.
Dim bIncludeBom As Boolean = False
Dim payloadStr As String = "In our village, folks say God crumbles up the old moon into stars."
jws.SetPayload(payloadStr,"utf-8",bIncludeBom)

' Create the JWS
' By default, the compact serialization is used.
Dim jwsCompact As String = jws.CreateJws()
If (jws.LastMethodSuccess <> True) Then
    Debug.WriteLine(jws.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("JWS: " & jwsCompact)

' Note: ECC signatures use random values, so the output will be different each time a signature is produced.
' sample output:
' JWS: eyJhbGciOiJFUzUxMiJ9.SW4gb3VyIHZpbGxhZ2UsIGZvbGtzIHNheSBHb2QgY3J1bWJsZXMgdXAgdGhlIG9sZCBtb29uIGludG8gc3RhcnMu.AFOnOtZ8UTp-ed1PfLfXxwGU7zT_jnmGGxew-d1CP6SfKa5RUhav5mF4szhSof22JaoQ742VIa0eZ0s1rhBnj8y6APr6g6vKzIpYZlJsnjzjUwAjDQOLmcsjxrrRfATh-NEv7G0Z9FrjdJasS44tCG2EnG6aT2TW-sPG0dy5o9jUWCzi


' Now load the JWS, validate, and recover the original text.
Dim jws2 As New Chilkat.Jws

' Load the JWS.
success = jws2.LoadJws(jwsCompact)

Dim eccPubKey As Chilkat.PublicKey = eccKey.GetPublicKey()

' Set the ECC public key used for validation.
signatureIndex = 0
jws2.SetPublicKey(signatureIndex,eccPubKey)


' Validate the 1st (and only) signature at index 0..
Dim v As Integer = jws2.Validate(signatureIndex)
If (v < 0) Then
    ' Perhaps Chilkat was not unlocked or the trial expired..
    Debug.WriteLine("Method call failed for some other reason.")
    Debug.WriteLine(jws2.LastErrorText)
    Exit Sub
End If

If (v = 0) Then
    Debug.WriteLine("Invalid signature.  The ECC key was incorrect, the JWS was invalid, or both.")
    Exit Sub
End If


' If we get here, the signature was validated..
Debug.WriteLine("Signature validated.")

' Recover the original content:
Debug.WriteLine(jws2.GetPayload("utf-8"))

' Examine the protected header:
Dim joseHeader As Chilkat.JsonObject = jws2.GetProtectedHeader(signatureIndex)
If (jws2.LastMethodSuccess <> True) Then
    Debug.WriteLine("No protected header found at the given index.")
    Exit Sub
End If

joseHeader.EmitCompact = False

Debug.WriteLine("Protected (JOSE) header:")
Debug.WriteLine(joseHeader.Emit())


' Output:
' 	Signature validated.
' 	In our village, folks say God crumbles up the old moon into stars.
' 	Protected (JOSE) header:
' 	{
' 	  "alg": "ES512"
' 	}