VB.NET

Create a JWS Using ECDSA P-256 SHA-256

See more JSON Web Signatures (JWS) Examples

Creates and validates a JSON Web Signature (JWS) that uses ECDSA P-256 SHA-256 VB.NET

Dim success As Boolean = False

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.

' Use the following ECC key loaded from JWK format.
Dim sbJwk As New Chilkat.StringBuilder
sbJwk.Append("{""kty"":""EC"",")
sbJwk.Append("""crv"":""P-256"",")
sbJwk.Append("""x"":""f83OJ3D2xF1Bg8vub9tLe1gHMzV76e8Tus9uPHvRVEU"",")
sbJwk.Append("""y"":""x_FEzRu9m36HLN_tue659LNpXW6pCyStikYjKIWI5a0"",")
sbJwk.Append("""d"":""jpsQnnGQmL-YBIffH1136cspYG6-0iY7X1fCE9-E9LI""")
sbJwk.Append("}")

Dim eccKey As New Chilkat.PrivateKey
' Note: This example loads the ECDSA key from JWK format.  Any format can be loaded
' into the private key object. (See the online reference documentation..)
success = eccKey.LoadJwk(sbJwk.GetAsString())
If (success = False) Then
    Debug.WriteLine(eccKey.LastErrorText)
    Exit Sub
End If


' Create the JWS Protected Header
Dim jwsProtHdr As New Chilkat.JsonObject
jwsProtHdr.AppendString("alg","ES256")

Dim jws As New Chilkat.Jws

' Set the protected header:
Dim signatureIndex As Integer = 0
jws.SetProtectedHeader(signatureIndex,jwsProtHdr)

' Set the ECC key:
jws.SetPrivateKey(signatureIndex,eccKey)

' Set the payload.
Dim bIncludeBom As Boolean = False
Dim payloadStr As String = "In our village, folks say God crumbles up the old moon into stars."
jws.SetPayload(payloadStr,"utf-8",bIncludeBom)

' Create the JWS
' By default, the compact serialization is used.
Dim jwsCompact As String = jws.CreateJws()
If (jws.LastMethodSuccess = False) Then
    Debug.WriteLine(jws.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("JWS: " & jwsCompact)

' Note: ECC signatures use random values, so the output will be different each time a signature is produced.
' sample output:
' JWS: eyJhbGciOiJFUzI1NiJ9.SW4gb3VyIHZpbGxhZ2UsIGZvbGtzIHNheSBHb2QgY3J1bWJsZXMgdXAgdGhlIG9sZCBtb29uIGludG8gc3RhcnMu.J6EGTNkeuEjehHHBu0SOKzifm8r35wbx49A5964pxzB7gannyZZPMkK7vmlaPJ-K8Xmm8cZsQySAPC12Xd8avw

' Now load the JWS, validate, and recover the original text.
Dim jws2 As New Chilkat.Jws

' Load the JWS.
success = jws2.LoadJws(jwsCompact)

Dim eccPubKey As New Chilkat.PublicKey
eccKey.ToPublicKey(eccPubKey)

' Set the ECC public key used for validation.
signatureIndex = 0
jws2.SetPublicKey(signatureIndex,eccPubKey)

' Validate the 1st (and only) signature at index 0..
Dim v As Integer = jws2.Validate(signatureIndex)
If (v < 0) Then
    ' Perhaps Chilkat was not unlocked or the trial expired..
    Debug.WriteLine("Method call failed for some other reason.")
    Debug.WriteLine(jws2.LastErrorText)
    Exit Sub
End If

If (v = 0) Then
    Debug.WriteLine("Invalid signature.  The ECC key was incorrect, the JWS was invalid, or both.")
    Exit Sub
End If


' If we get here, the signature was validated..
Debug.WriteLine("Signature validated.")

' Recover the original content:
Debug.WriteLine(jws2.GetPayload("utf-8"))

' Examine the protected header:
Dim joseHeader As New Chilkat.JsonObject
jws2.GetProtectedH(signatureIndex,joseHeader)
joseHeader.EmitCompact = False

Debug.WriteLine("Protected (JOSE) header:")
Debug.WriteLine(joseHeader.Emit())

' Output:

' Signature validated.
' In our village, folks say God crumbles up the old moon into stars.
' Protected (JOSE) header:
' { 
'   "alg": "ES256"
' }