(VB.NET) Create Egypt ITIDA CAdES-BES Signature with Automatic JSON Canonicalization

See more Egypt ITIDA Examples

Demonstrates how to create a .p7s signature that fits Egypt's ITIDA requirements where Chilkat automatically does the ITIDA JSON canonicalization.

Note: This example requires Chilkat v9.5.0.75 or greater.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New Chilkat.Crypt2
crypt.VerboseLogging = True

Dim cert As New Chilkat.Cert
cert.VerboseLogging = True

' Set the smart card PIN, which will be needed for signing.
cert.SmartCardPin = "12345678"

' There are many ways to load the certificate.  
' This example was created for a customer using an ePass2003 USB token.
' Assuming the USB token is the only source of a hardware-based private key..
Dim success As Boolean = cert.LoadFromSmartcard("")
If (success <> True) Then
    Debug.WriteLine(cert.LastErrorText)
    Exit Sub
End If


' Tell the crypt class to use this cert.
success = crypt.SetSigningCert(cert)
If (success <> True) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


Dim cmsOptions As New Chilkat.JsonObject
' Setting "DigestData" causes OID 1.2.840.113549.1.7.5 (digestData) to be used.
cmsOptions.UpdateBool("DigestData",True)
cmsOptions.UpdateBool("OmitAlgorithmIdNull",True)

' Indicate that we are passing normal JSON and we want Chilkat do automatically
' do the ITIDA JSON canonicalization:
cmsOptions.UpdateBool("CanonicalizeITIDA",True)

crypt.CmsOptions = cmsOptions.Emit()


' The CadesEnabled property applies to all methods that create CMS/PKCS7 signatures. 
' To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = True

crypt.HashAlgorithm = "sha256"

Dim jsonSigningAttrs As New Chilkat.JsonObject
jsonSigningAttrs.UpdateInt("contentType",1)
jsonSigningAttrs.UpdateInt("signingTime",1)
jsonSigningAttrs.UpdateInt("messageDigest",1)
jsonSigningAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSigningAttrs.Emit()

' By default, all the certs in the chain of authentication are included in the signature.
' If desired, we can choose to only include the signing certificate:
crypt.IncludeCertChain = False

' Pass a JSON document such as the following.  Chilkat will do the ITIDA canonicalization.
' (It is the canonicalized JSON that gets signed.)

'       {
'          "issuer":{
'             "address":{
'                "branchID":"0",
'                "country":"EG",
'                "regionCity":"Cairo",
'                "postalCode":"",
'                "buildingNumber":"0",
'                "street":"123rd Street",
'                "governate":"GOVERNATE"
'             },
'             "type":"B",
'             "id":"209999899",
'             "name":"Xyz SAE"
'          },
'          "receiver":{
'             "address":{
'                "country":"EG",
'                "regionCity":"CAIRO",
'                "postalCode":"11435",
'                "buildingNumber":"0",
'                "street":"Autostrad Road Abc",
'                "governate":"GOVERNATE"
'             },
'             "type":"B",
'             "id":"999999999",
'             "name":"XYZ EGYPT FOR TRADE"
'          },
'          "documentType":"I",
'          "documentTypeVersion":"1.0",
'          "dateTimeIssued":"2020-11-15T11:04:53Z",
'          "taxpayerActivityCode":"1073",
'          "internalID":"ZZZZ999",
'          "purchaseOrderReference":"2009199918",
'          "salesOrderReference":"",
'          "payment":{
'             "bankName":"",
'             "bankAddress":"",
'             "bankAccountNo":"",
'             "bankAccountIBAN":"",
'             "swiftCode":"",
'             "terms":""
'          },
'          "delivery":{
'             "approach":"",
'             "packaging":"",
'             "dateValidity":"",
'             "exportPort":"",
'             "countryOfOrigin":"EG",
'             "grossWeight":0,
'             "netWeight":0,
'             "terms":""
'          },
'          "invoiceLines":[
'             {
'                "description":"CDM Widget 48GX99X12BA",
'                "itemType":"GS1",
'                "itemCode":"7622213335056",
'                "unitType":"CS",
'                "quantity":1.00,
'                "unitValue":{
'                   "currencySold":"EGP",
'                   "amountEGP":588.67,
'                   "amountSold":0,
'                   "currencyExchangeRate":0
'                },
'                "salesTotal":588.67,
'                "total":603.97,
'                "valueDifference":0,
'                "totalTaxableFees":0,
'                "netTotal":529.8,
'                "itemsDiscount":0,
'                "discount":{
'                   "rate":10.00,
'                   "amount":58.87
'                },
'                "taxableItems":[
'                   {
'                      "taxType":"T1",
'                      "amount":74.17,
'                      "subType":"No sub",
'                      "rate":14.00
'                   }
'                ],
'                "internalCode":"9099994"
'             }
'          ],
'          "totalSales":588.67,
'          "totalSalesAmount":588.67,
'          "totalDiscountAmount":58.87,
'          "netAmount":529.80,
'          "taxTotals":[
'             {
'                "taxType":"T1",
'                "amount":74.17
'             }
'          ],
'          "extraDiscountAmount":0,
'          "totalItemsDiscountAmount":0,
'          "totalAmount":603.97,
'       }
' 


Dim json As New Chilkat.JsonObject
success = json.LoadFile("qa_data/itida/sdk.invoicing.eta.gov.eg/files/one-doc.json")
If (success = False) Then
    Debug.WriteLine(json.LastErrorText)
    Exit Sub
End If

json.EmitCompact = False

' Create the CAdES-BES signature.
crypt.EncodingMode = "base64"

' Make sure we sign the utf-8 byte representation of the JSON string
crypt.Charset = "utf-8"

Dim sigBase64 As String = crypt.SignStringENC(json.Emit())
If (crypt.LastMethodSuccess = False) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("Base64 signature:")
Debug.WriteLine(sigBase64)

' Add the signature to the JSON.
json.UpdateString("signatures[0].signatureType","I")
json.UpdateString("signatures[0].value",sigBase64)

Debug.WriteLine("JSON with signature added:")
Debug.WriteLine(json.Emit())