(VB.NET) HTTP multipart-mixed POST (for a UPS Package Level Detail PLD Request)

Important: This example requires Chilkat v9.5.0.59 or greater.

Demonstrates how to create a POST for a UPS Package Level Detail PLD Request. The request must be a multipart-mixed request having two sub-parts. The first is a application/x-www-form-urlencoded with name=value URL encoded pairs. The second is a application/x-ups-binary containing a UPS PLD request.

The HTTP request created by this example looks like this:

POST /hapld/tos/kdwhapltos HTTP/1.1
Content-Type: multipart/mixed; boundary=------------050801040202040701030308
Host: domain
Content-Length: 658

--------------050801040202040701030308
Content-type: application/x-www-form-urlencoded
Content-length: 134

AppVersion=1.0&AcceptUPSLicenseAgreement=YES&VersionNumber=V4R1&UserId=myUser&Password=myPassword&ResponseType=application/x-ups-pld

--------------050801040202040701030308
Content-type: application/x-ups-binary
Content-length: 721

020094 2014041500000594196532600 000000001*AAV0Y203 DE 5941965326000001*BA1ZV0Y2036650001829 00001+0000000000000012 +0000000000000000KGS07COL10 3CMEUR000001*CA18TC239 AOK Bahnhofstr. Dresden 01099 DE *EAEVS+000000000000104200EUR*PA1ZV0Y2036650001829 02+0000012 +0000000+00000000+00000000+00000000*SA000005

--------------050801040202040701030308--

The HTTP response (if successful) is multipart MIME as shown below. This example will extract the response content using the Chilkat MIME API.

Content-type: text/html
Content-length: 138

<HTML>
<HEAD>
<TITLE>UPS Internet Software</TITLE>
</HEAD>
<BODY>
<P>UPS Internet Software, Copyright UPS 1998</P>
</BODY>
</HTML>

--BOUNDARY
Content-type: application/x-ups-psmpld
Content-length: 104

UPSOnLine%1.0%0000%0000Successful completion - No errors found.                                    

--BOUNDARY
Content-type: application/x-ups-pld
Content-length: 800

000200000787300000640 KDGPLCR1                   United Parcel Service                      09/06/16  Page:1                    Test PLD Control Report                     05:44 PM                                                                                  ------------------------------------------------------------------------------- Pickup Date:20030813 Sequence#:000005900000002 #of Segments:000000000000000005                                                                                                                                                                  Shipper#:0TEST0     Book/Page#:5900000002 Shipments:000001 Packages:0000000001 10000012900000000Successful completion - No errors found.                                        
!!! Test Upload !!!
File Uploaded: n/a

--BOUNDARY--

Chilkat .NET Downloads

Chilkat .NET Framework

Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Boolean

Dim req As New Chilkat.HttpRequest

' The ContentType, HttpVerb, and Path properties should
' always be explicitly set.
req.HttpVerb = "POST"
req.Path = "/hapld/tos/kdwhapltos"
req.ContentType = "multipart/mixed"

' The 1st body of the multipart/mixed HTTP request will have a content-type of application/x-www-form-urlencoded
' It contains URL encoded parameters.
' We'll use a temporary HTTP request object solely for the purpose of generating our URL encoded parameter string.
Dim paramEncoder As New Chilkat.HttpRequest
paramEncoder.AddParam("AppVersion","1.0")
paramEncoder.AddParam("AcceptUPSLicenseAgreement","YES")
paramEncoder.AddParam("VersionNumber","V4R1")
paramEncoder.AddParam("UserId","UPS_USERID")
paramEncoder.AddParam("Password","UPS_PASSWORD")
Dim urlEncodedParams As String = paramEncoder.GetUrlEncodedParams()

' The UPS server wants all params to be URL encoded except for the ResponseType param.
' Therefore, we'll add ResponseType unencoded at the end, like this:
Dim sbParams As New Chilkat.StringBuilder
sbParams.Append(urlEncodedParams)
sbParams.Append("&ResponseType=application/x-ups-pld")
' Also, it is very important to include a CRLF at the end.  (This is to satisfy undocumented details
' required by the UPS PLD server.)
sbParams.Append(vbCrLf)

' Add the params as the 1st sub-part of the multipart/mixed request
req.AddStringForUpload2("","",sbParams.GetAsString(),"","application/x-www-form-urlencoded")

' Now for the 2nd part (using some junk data found on the developerkitcommunity.ups.com site.
' Notice the CRLF at the end of the string.  This is important.
Dim pld As String = "020094                                  2003081300000590000000200   000000001*AA0TEST0    DE                5900000002000001*BA1Z0TEST06800000018                 00001+0000000000000010 +0000000000000000KGS11PRE10                                   3CMEUR000001*CA18                                   United Parcel Service              Goerlitzer Str 1                                                                                         Neuss                              41460    DE                                                        *PA1Z0TEST06800000018                 02+0000010                                                                                      +0000000+00000000+00000000+00000000*SA000004" & vbCrLf

req.AddStringForUpload2("","",pld,"","application/x-ups-binary")

' The UPS PLD server requires Content-Length headers within the MIME sub-parts of the request.
' A new feature of Chilkat v9.5.0.59 is if a Content-Length sub-header is added (with an arbitrary value, such as 0),
' then Chilkat will compute the actual sub-part size and replace the value when the request is sent.
req.AddSubHeader(0,"Content-Length","0")
req.AddSubHeader(1,"Content-Length","0")


' A few important comments about the HTTP request that is generated:
' 
' 1) Chilkat automatically generates a random boundary string.   In 99.999% of cases, this should 
'    be sufficient.
' 2) The top-level Content-Length header is automatically generated based on the actual length of the MIME message
'    that follows the intial (topmost) MIME header.
' 3) The HOST header will automatically get filled in with the actual domain when SynchronousRequest
'    method is called.

' Now send the request...
Dim http As New Chilkat.Http

' If desired (for debugging), provide a flie path for a session log.
' The session log can be sent to support@chilkatsoft.com if the PLD request fails.
http.SessionLogFilename = "c:/aaworkarea/ups_pld/sessionLog.txt"

' Send the PLD request over TLS..
Dim resp As Chilkat.HttpResponse = http.SynchronousRequest("www.pld-certify.ups.com",443,True,req)
If (http.LastMethodSuccess <> True) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


' Load the response MIME.
Dim mime As New Chilkat.Mime
mime.LoadMime(resp.FullMime)

' If it does not have 3 sub-parts, then something is amiss...
If (mime.NumParts <> 3) Then
    Debug.WriteLine("Unexpected number of MIME parts.")
    Debug.WriteLine(resp.FullMime)
    Exit Sub
End If


' Examine each response part.
Dim part0 As Chilkat.Mime = mime.GetPart(0)
Debug.WriteLine("---- text/html part ----")
Debug.WriteLine(part0.GetBodyDecoded())

Dim part1 As Chilkat.Mime = mime.GetPart(1)
Debug.WriteLine("---- application/x-ups-psmpld part ----")
Debug.WriteLine(part1.GetBodyDecoded())

Dim part2 As Chilkat.Mime = mime.GetPart(2)
Debug.WriteLine("---- application/x-ups-pld part ----")
Debug.WriteLine(part2.GetBodyDecoded())