(VB.NET) Upload File from String

Uploads a text file where the contents of the file are contained in a string variable.

See Google Drive Files: create for more details.

Also See Google Drive Multipart Upload for more details.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

Dim success As Boolean = True

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses a previously obtained access token having permission for the 
' Google Drive scope.

Dim gAuth As New Chilkat.AuthGoogle
gAuth.AccessToken = "GOOGLE-DRIVE-ACCESS-TOKEN"

Dim rest As New Chilkat.Rest

' Connect using TLS.
Dim bAutoReconnect As Boolean = True
success = rest.Connect("www.googleapis.com",443,True,bAutoReconnect)

' Provide the authentication credentials (i.e. the access token)
rest.SetAuthGoogle(gAuth)

' A multipart upload to Google Drive needs a multipart/related Content-Type
rest.AddHeader("Content-Type","multipart/related")

' Specify each part of the request.

' The 1st part is JSON with information about the file.
rest.PartSelector = "1"
rest.AddHeader("Content-Type","application/json; charset=UTF-8")

Dim json As New Chilkat.JsonObject
json.AppendString("name","helloWorld.txt")
json.AppendString("description","A simple text file that says Hello World.")
json.AppendString("mimeType","text/plain")
rest.SetMultipartBodyString(json.Emit())

' The 2nd part is the file content.
' In this case, we'll upload a simple text file containing "Hello World!"
rest.PartSelector = "2"
rest.AddHeader("Content-Type","text/plain")

Dim fileContents As String = "Hello World!"
rest.SetMultipartBodyString(fileContents)

Dim jsonResponse As String = rest.FullRequestMultipart("POST","/upload/drive/v3/files?uploadType=multipart")
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Debug.WriteLine("response JSON: " & jsonResponse)
    Exit Sub
End If


' Show the JSON response.
json.Load(jsonResponse)

' Show the full JSON response.
json.EmitCompact = False
Debug.WriteLine(json.Emit())

' A successful response looks like this:
' {
'   "kind": "drive#file",
'   "id": "0B53Q6OSTWYoldmJ0Z3ZqT2x5MFk",
'   "name": "Untitled",
'   "mimeType": "text/plain"
' }

' Get the fileId:
Debug.WriteLine("fileId: " & json.StringOf("id"))