(VB.NET) Google Drive - Resumable Upload

Demonstrates how to do a resumable upload to Google Drive.

For more information, see https://developers.google.com/drive/api/v3/manage-uploads#resumable

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Boolean = True

' This example uses a previously obtained access token having permission for the 
' Google Drive scope. 
' See Get Google Drive OAuth2 Access Token

Dim http As New Chilkat.Http

http.AuthToken = "GOOGLE_DRIVE_ACCESS_TOKEN"

' First we want to initiate the resumable upload.
' We send a POST to get a session URI, which will be used to upload the file, and resume if needed.

' Our POST will look like this:

' POST https://www.googleapis.com/upload/drive/v3/files?uploadType=resumable HTTP/1.1
' Authorization: Bearer [YOUR_AUTH_TOKEN]          <-- Chilkat automatically adds this header because the AuthToken property was set.
' Content-Length: 38                               <-- Chilkat will automatically add this header.
' Content-Type: application/json; charset=UTF-8    <-- This is the type of this POST, and is specified in the call to PostJson3.
' X-Upload-Content-Type: application/zip           <-- The type of file we'll be uploading
' X-Upload-Content-Length: 1366807                 <-- The size of the file we'll be uploading
' 
' {
'   "name": "myObject"
' }


http.SetRequestHeader("X-Upload-Content-Type","application/zip")
http.SetRequestHeader("X-Upload-Content-Length","1366807")

Dim json As New Chilkat.JsonObject
json.UpdateString("name","myZip")

Dim resp As Chilkat.HttpResponse = http.PostJson3("https://www.googleapis.com/upload/drive/v3/files?uploadType=resumable","application/json",json)
If (http.LastMethodSuccess = False) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


Dim statusCode As Integer = resp.StatusCode
If (statusCode <> 200) Then
    Debug.WriteLine(resp.BodyStr)
    Debug.WriteLine("response status = " & statusCode)
    Exit Sub
End If


' The session URI is in the "Location" response header:
Dim sbSessionUri As New Chilkat.StringBuilder
sbSessionUri.Append(resp.GetHeaderField("Location"))
Dim sessionUri As String = sbSessionUri.GetAsString()
Debug.WriteLine("Session URI: " & sessionUri)



' Here's a sample session URI:  https://www.googleapis.com/upload/drive/v3/files?uploadType=resumable&upload_id=AEnB2UrszR8lDqlo3mtXJw_0rYI_Hi1oVh1NPFcLfoyBq9NcSjk85kFopoZaVEgT38OSmLl0XsObPf4iCSJwHlrOvvIJQ_ckIQ

' -----------------------------------------------------------------------------
' The next step is to upload the file using the session URI:

' We'll send a PUT that looks like this:

' PUT https://www.googleapis.com/upload/drive/v3/files?uploadType=resumable&upload_id=xa298sd_sdlkj2 HTTP/1.1
' Content-Length: 1366807
' Content-Type: application/zip
' 
' [BYTES 0-1366806]

' First remove the X-Upload-Content-Type and X-Upload-Content-Length request headers we specified earlier, so they don't get sent with subsequent requests.
http.ClearHeaders()

' Because the file is likely large, we'll use SynchronousRequest which allows to to pass an HTTP request object where the body can be streamed directly from a file.
Dim req As New Chilkat.HttpRequest

req.ContentType = "application/zip"
req.HttpVerb = "PUT"

Dim url As New Chilkat.Url
url.ParseUrl(sessionUri)

req.Path = url.PathWithQueryParams
Debug.WriteLine("Path with Query Param: " & url.PathWithQueryParams)

' Specify that the request body is to be streamed directly from a file.
success = req.StreamBodyFromFile("qa_data/zips/big.zip")
If (success = False) Then
    Debug.WriteLine(req.LastErrorText)
    Exit Sub
End If


resp = http.SynchronousRequest(url.Host,url.Port,url.Ssl,req)
If (http.LastMethodSuccess = False) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


Debug.WriteLine(resp.BodyStr)
Debug.WriteLine("response status = " & statusCode)

' Sample output:

' {
'  "kind": "drive#file",
'  "id": "1rx20i53eurtkVQ-RT7Ry8Ct85PgPYMET",
'  "name": "myZip",
'  "mimeType": "application/zip"
' }
' 
' response status = 200