VB.NET
Send GMail with BCC Recipients using REST API

Demonstrates how to send an email with BCC recipients using the GMail REST API.
Chilkat VB.NET Downloads

VB.NET
Dim success As Boolean = False

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Use the Chilkat Email API to create or load an email.
Dim email As New Chilkat.Email

' The From name/address don't need to be specified. 
' GMail will automatically use your Gmail address if the following 2 lines are omitted.
email.FromName = "My Name"
email.FromAddress = "my_account_name@gmail.com"

email.AddTo("John Smith","somebody@somewhere.com")
' To add more recipients, make additional calls to AddTo or AddCC, one per recipient...

' -----------------------------------------------------------------------------------------
' This section of this example demonstrates how to add BCC recipients.
' 
' Technically, an email should never contain a "Bcc" MIME header because it would
' effectively nullify the purpose of BCC -- which means "Blind Carbon Copy".
' Email recipients should not be able to see the BCC recipients.
' Chilkat never adds a "Bcc" header field.
' However.. in this case, the GMail REST server will look for the Bcc header field,
' and will include those email addresses when sending, and also removes the Bcc header
' from the email that is sent.
' 
' Starting in Chilkat v9.5.0.91, we can tell the email object to add the Bcc header
' using the "UseBccHeader" UncommonOptions.  For example:
email.UncommonOptions = "UseBccHeader"
email.AddBcc("Joe","joe@example.com")
email.AddBcc("Dave","dave@example.com")
' ...
' -----------------------------------------------------------------------------------------

email.Subject = "This is a test GMail email created using Chilkat."
email.Charset = "utf-8"
email.AddPlainTextAlternativeBody("This is a test")

' Create an HTML email body with an embedded image.
Dim cid As String = email.AddRelatedFile("qa_data/jpg/starfish.jpg")
Dim sbHtml As New Chilkat.StringBuilder
sbHtml.Append("<html><body>This is a <b>test</b><br><img src=""cid:STARFISH_CID""/></body></html>")
Dim numReplacements As Integer = sbHtml.Replace("STARFISH_CID",cid)

email.AddHtmlAlternativeBody(sbHtml.GetAsString())

' OK.. we now have an HTML email with an embedded JPG image
' We'll need to get the full MIME of the email encoded to a base64url string.
Dim sbMime As New Chilkat.StringBuilder
email.GetMimeSb(sbMime)
sbMime.Encode("base64url","utf-8")

' The body of the HTTP request will be JSON..
Dim json As New Chilkat.JsonObject
json.UpdateSb("raw",sbMime)

' Send the email...
Dim http As New Chilkat.Http
http.AuthToken = "GMAIL-ACCESS-TOKEN"

Dim url As String = "https://www.googleapis.com/gmail/v1/users/me/messages/send"
Dim resp As New Chilkat.HttpResponse
success = http.HttpJson("POST",url,json,"application/json",resp)
If (success = False) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


' A status code of 200 indicates success.
Debug.WriteLine("Response status code: " & resp.StatusCode)
Debug.WriteLine("Response body:")
Debug.WriteLine(resp.BodyStr)

' The response body contains JSON.
' Use the online tool at Generate JSON Parsing Code
' to generate JSON parsing code.

' A sample successful JSON response:

' {
'  "id": "166f0d4ac39e50bf",
'  "threadId": "166f0d4ac39e50bf",
'  "labelIds": [
'   "SENT"
'  ]
' }