(VB.NET) Firebase Receive Server-Sent Events (text/event-stream)

Demonstrates how to start receiving server-sent events and update your JSON database with each event.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' Demonstrates how to begin receiving server-sent events, and to update
' your JSON database for each event.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example assumes a JWT authentication token, if required, has been previously obtained.
' See Get Firebase Access Token from JSON Service Account Private Key for sample code.


' Load the previously obtained Firebase access token into a string.
Dim fac As New Chilkat.FileAccess
Dim accessToken As String = fac.ReadEntireTextFile("qa_data/tokens/firebaseToken.txt","utf-8")
If (fac.LastMethodSuccess <> True) Then
    Debug.WriteLine(fac.LastErrorText)
    Exit Sub
End If


Dim rest As New Chilkat.Rest

' Make the initial connection (without sending a request yet).
' Once connected, any number of requests may be sent.  It is not necessary to explicitly
' call Connect before each request.  
Dim success As Boolean = rest.Connect("chilkat.firebaseio.com",443,True,True)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If

Dim authGoogle As New Chilkat.AuthGoogle
authGoogle.AccessToken = accessToken
rest.SetAuthGoogle(authGoogle)

rest.AddHeader("Accept","text/event-stream")
rest.AddHeader("Cache-Control","no-cache")

Dim responseBody As String = rest.FullRequestNoBody("GET","/.json")

' A 307 redirect response is expected.
If (rest.ResponseStatusCode <> 307) Then
    Debug.WriteLine("Unexpected response code: " & rest.ResponseStatusCode)
    Debug.WriteLine(responseBody)
    Debug.WriteLine("Failed.")
    Exit Sub
End If



' Get the redirect URL
Dim url As Chilkat.Url = rest.RedirectUrl()
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If

Debug.WriteLine("redirect URL domain: " & url.Host)
Debug.WriteLine("redirect URL path: " & url.Path)
Debug.WriteLine("redirect URL query params: " & url.Query)
Debug.WriteLine("redirect URL path with query params: " & url.PathWithQueryParams)

' Our text/event-stream will be obtained from the redirect URL...
Dim rest2 As New Chilkat.Rest

success = rest2.Connect(url.Host,443,True,True)
If (success <> True) Then
    Debug.WriteLine(rest2.LastErrorText)

    Exit Sub
End If


rest2.AddHeader("Accept","text/event-stream")
rest2.AddHeader("Cache-Control","no-cache")

' Add the redirect query params to the request
rest2.AddQueryParams(url.Query)

' In our case, we don't actually need the auth query param,
' so remove it.
rest2.RemoveQueryParam("auth")

' Send the request.  (We are only sending the request here.
' We are not yet getting the response because the response
' will be a text/event-stream.)
success = rest2.SendReqNoBody("GET",url.Path)
If (success <> True) Then
    Debug.WriteLine(rest2.LastErrorText)

    Exit Sub
End If




' Read the response header.  
' We want to first get the response header to see if it's a successful
' response status code.  If not, then the response will not be a text/event-stream
' and we should read the response body normally.
Dim responseStatusCode As Integer = rest2.ReadResponseHeader()
If (responseStatusCode < 0) Then
    Debug.WriteLine(rest2.LastErrorText)
    Exit Sub
End If


' If successful, a 200 response code is expected.
' If the reponse code is not 200, then read the response body and fail..
If (responseStatusCode <> 200) Then
    Debug.WriteLine("Response Code: " & responseStatusCode)
    Debug.WriteLine("Response Status Text: " & rest2.ResponseStatusText)
    Debug.WriteLine("Response Header: " & rest2.ResponseHeader)
    responseBody = rest2.ReadRespBodyString()
    If (rest2.LastMethodSuccess = True) Then
        Debug.WriteLine("Error Response Body: " & responseBody)
    End If

    Debug.WriteLine("Failed.")
    Exit Sub
End If


' For this example, our JSON database will be empty at the beginning.
' The incoming events (put and patch) will be applied to this database.
Dim jsonDb As New Chilkat.JsonObject

' Make sure to set the JSON path delimiter to "/".  The default is "." and this
' is not compatible with Firebase paths.
jsonDb.DelimiterChar = "/"

' At this point, we've received the response header.  Now it's time to begin
' receiving the event stream.  We'll start a background thread to read the 
' stream.  (Our main application (foreground) thread can cancel it at any time.)  
' While receiving in the background thread, our foreground thread can read the stream
' as it desires..
Dim eventStream As New Chilkat.Stream

' This sse object will be used as a helper to parse the server-sent event stream.
Dim sse As New Chilkat.ServerSentEvent

Dim task As Chilkat.Task = rest2.ReadRespBodyStreamAsync(eventStream,True)
task.Run()

' For this example, we'll just read a few events, and then cancel the
' async task.
Dim count As Integer = 0
While (count < 3) And (task.Finished = False)

    ' Get the next event, which is a series of text lines ending with
    ' a blank line. 
    ' Note: This method blocks the calling thread until a message arrives.
    ' a program might instead periodically check the availability of
    ' data via the stream's DataAvailable property, and then do the read.

    ' An alternative to writing a while loop to read the event stream
    ' would be to setup some sort of timer event in your program (using whatever timer functionality
    ' is provided in a programming language/environment), to periodically check the eventStream's
    ' DataAvailable property and consume the incoming event.
    Dim eventStr As String = eventStream.ReadUntilMatch(vbCrLf & vbCrLf)
    If (eventStream.LastMethodSuccess <> True) Then
        Debug.WriteLine(eventStream.LastErrorText)
        ' Force the loop to exit by setting the count to a high number.
        count = 99999
    Else
        Debug.WriteLine("Event: [" & eventStr & "]")

        ' We have an event. Let's update our local copy of the JSON database.
        success = sse.LoadEvent(eventStr)
        If (success <> True) Then
            Debug.WriteLine("Failed to load sse event: " & eventStr)
        Else
            ' Now we can easily access the event name and data, and apply it to our JSON database:
            success = jsonDb.FirebaseApplyEvent(sse.EventName,sse.Data)
            If (success <> True) Then
                Debug.WriteLine("Failed to apply event: " & sse.EventName & ": " & sse.Data)
            Else
                Debug.WriteLine("Successfully applied event: " & sse.EventName & ": " & sse.Data)
            End If

        End If

    End If

    count = count + 1
End While

' Make sure the background task is cancelled if still running.
task.Cancel()



' Examine the JSON database after applying events..
jsonDb.EmitCompact = False
Debug.WriteLine("----")
Debug.WriteLine(jsonDb.Emit())