(VB.NET) FatturaPA XML Invoice Sign+Encrypt to P7M

Demonstrates how to create a CAdES BES signed + encrypted invoice.xml.p7m for the Italian FatturaPA exchange system.

Note: This example requires Chilkat v9.5.0.75 or greater.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' Note: Requires Chilkat v9.5.0.75 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New Chilkat.Crypt2

' Use a digital certificate and private key from a PFX file (.pfx or .p12).
Dim pfxPath As String = "qa_data/pfx/cert_test123.pfx"
Dim pfxPassword As String = "test123"

Dim cert As New Chilkat.Cert
Dim success As Boolean = cert.LoadPfxFile(pfxPath,pfxPassword)
If (success <> True) Then
    Debug.WriteLine(cert.LastErrorText)
    Exit Sub
End If


' Provide the signing cert (with associated private key).
success = crypt.SetSigningCert(cert)
If (success <> True) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


' Indicate that SHA-256 should be used.
crypt.HashAlgorithm = "sha256"

' Specify the signed attributes to be included.
' (This is what makes it CAdES-BES compliant.)
Dim jsonSignedAttrs As New Chilkat.JsonObject
jsonSignedAttrs.UpdateInt("contentType",1)
jsonSignedAttrs.UpdateInt("signingTime",1)
jsonSignedAttrs.UpdateInt("messageDigest",1)
jsonSignedAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSignedAttrs.Emit()

Dim inFile As String = "qa_data/xml/IT01234567890_11002.xml"
Dim sigFile As String = "qa_data/fatturapa/signed.p7m"

' Create the CAdES-BES signature, which contains the original data.
success = crypt.CreateP7M(inFile,sigFile)
If (success = False) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


' Now we'll encrypt what was signed using FatturaPA's certificate (from a PEM file)
Dim encryptCert As New Chilkat.Cert
success = encryptCert.LoadFromFile("qa_data/certs/fatturapa_cert.pem")
If (success <> True) Then
    Debug.WriteLine(encryptCert.LastErrorText)
    Exit Sub
End If


crypt.CryptAlgorithm = "pki"

success = crypt.SetEncryptCert(encryptCert)
If (success <> True) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


' Indicate the underlying bulk encryption algorithm to be used:
crypt.Pkcs7CryptAlg = "aes"
crypt.KeyLength = 128

' There's one last option that could be set.  If is the RSA encryption encryption/padding scheme. 
' By default, RSAES_PKCS1-V1_5 is used.  If desired, the OaepPadding property could be set to True to
' use RSAES_OAEP.  (We'll leave it set at the default value of False)
crypt.OaepPadding = False

' Everything is specified.  Encrypt the .p7m to create a new .p7m (which adds a layer of encryption around the opaque signature).
' The output is PKCS7 in binary DER format.
success = crypt.CkEncryptFile(sigFile,"qa_output/signed_and_encrypted.p7m")
If (success <> True) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("Success.")