(VB.NET) Get E-way Bill System Access Token

Sends a request to get an E-way bill system access token.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.


'  First load the public key provided by the E-way bill System
Dim pubkey As New Chilkat.PublicKey
Dim success As Boolean = pubkey.LoadFromFile("qa_data/pem/eway_publickey.pem")
If (success <> True) Then
    Debug.WriteLine(pubkey.LastErrorText)
    Exit Sub
End If


'  Encrypt the password using the RSA public key provided by eway..
Dim password As String = "my_wepgst_password"
Dim rsa As New Chilkat.Rsa
rsa.Charset = "utf-8"
rsa.EncodingMode = "base64"

success = rsa.ImportPublicKeyObj(pubkey)
If (success <> True) Then
    Debug.WriteLine(rsa.LastErrorText)
    Exit Sub
End If


'  Returns the encrypted password as base64 (because the EncodingMode = "base64")
Dim encPassword As String = rsa.EncryptStringENC(password,False)
If (rsa.LastMethodSuccess <> True) Then
    Debug.WriteLine(rsa.LastErrorText)
    Exit Sub
End If


'  Generate a random app_key.  This should be 32 bytes (us-ascii chars)
'  We need 32 bytes because we'll be doing 256-bit AES ECB encryption, and 32 bytes = 256 bits.
Dim prng As New Chilkat.Prng
'  Generate a random string containing some numbers, uppercase, and lowercase.
Dim app_key As String = prng.RandomString(32,True,True,True)

Debug.WriteLine("app_key = " & app_key)

'  RSA encrypt the app_key.
Dim encAppKey As String = rsa.EncryptStringENC(app_key,False)
If (rsa.LastMethodSuccess <> True) Then
    Debug.WriteLine(rsa.LastErrorText)
    Exit Sub
End If


'  Prepare the JSON body for the HTTP POST that gets the access token.
Dim jsonBody As New Chilkat.JsonObject
jsonBody.UpdateString("action","ACCESSTOKEN")
'  Use your username instead of "09ABDC24212B1FK".
jsonBody.UpdateString("username","09ABDC24212B1FK")
jsonBody.UpdateString("password",encPassword)
jsonBody.UpdateString("app_key",encAppKey)

Dim http As New Chilkat.Http

'  Add required headers.
'  Use your ewb-user-id instead of "03AEXPR16A9M010"
http.SetRequestHeader("ewb-user-id","03AEXPR16A9M010")
'  The Gstin should be the same as the username in the jsonBody above.
http.SetRequestHeader("Gstin","09ABDC24212B1FK")
http.Accept = "application/json"

'  POST the JSON...
Dim resp As Chilkat.HttpResponse = http.PostJson2("http://ewb.wepgst.com/api/Authenticate","application/json",jsonBody.Emit())
If (http.LastMethodSuccess <> True) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


Dim respStatusCode As Integer = resp.StatusCode
Debug.WriteLine("response status code =" & respStatusCode)
Debug.WriteLine("response body:")
Debug.WriteLine(resp.BodyStr)

If (respStatusCode <> 200) Then

    Debug.WriteLine("Failed in some unknown way.")
    Exit Sub
End If


'  When the response status code = 200, we'll have either
'  success response like this:
'   {"status":"1","authtoken":"...","sek":"..."}
' 
'  or a failed response like this:
' 
'  {"status":"0","error":"eyJlcnJvckNvZGVzIjoiMTA4In0="}

'  Load the response body into a JSON object.
Dim json As New Chilkat.JsonObject
json.Load(resp.BodyStr)


Dim status As Integer = json.IntOf("status")
Debug.WriteLine("status = " & status)

If (status <> 1) Then
    '  Failed.  Base64 decode the error
    ' {"status":"0","error":"eyJlcnJvckNvZGVzIjoiMTA4In0="}
    '  For an invalid password, the error is: {"errorCodes":"108"}
    Dim sbError As New Chilkat.StringBuilder
    json.StringOfSb("error",sbError)
    sbError.Decode("base64","utf-8")
    Debug.WriteLine("error: " & sbError.GetAsString())
    Exit Sub
End If


'  At this point, we know the request was entirely successful.
Dim authToken As String = json.StringOf("authtoken")

'  Decrypt the sek key using our app_key.
Dim crypt As New Chilkat.Crypt2
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "ecb"
crypt.KeyLength = 256
crypt.SetEncodedKey(app_key,"us-ascii")
crypt.EncodingMode = "base64"

Dim bdSek As New Chilkat.BinData
bdSek.AppendEncoded(json.StringOf("sek"),"base64")
crypt.DecryptBd(bdSek)

'  bdSek now contains the decrypted symmetric encryption key...
'  We'll use it to encrypt the JSON payloads we send.

'  Let's persist our authtoken and decrypted sek (symmetric encryption key).
'  To send EWAY requests (such as to create an e-way bill), we'll just load
'  and use these pre-obtained credentials.
Dim jsonEwayAuth As New Chilkat.JsonObject
jsonEwayAuth.UpdateString("authToken",authToken)
jsonEwayAuth.UpdateString("decryptedSek",bdSek.GetEncoded("base64"))
jsonEwayAuth.EmitCompact = False

Dim fac As New Chilkat.FileAccess
fac.WriteEntireTextFile("qa_data/tokens/ewayAuth.json",jsonEwayAuth.Emit(),"utf-8",False)

Debug.WriteLine("Saved:")
Debug.WriteLine(jsonEwayAuth.Emit())

'  Sample output:
'  {
'    "authToken": "IBTeFtxNfVurg71LTzZ2r0xK7",
'    "decryptedSek": "5g1TyTie7yoslU3DrbYATa7mWyPazlODE7cEh5Vy4Ho="
'  }